CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 2.6)
2project(mGBA C)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=c99")
6else()
7 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
8endif()
9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
12set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
13set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
14set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
15set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
16set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
17set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
18set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
19set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
20set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
21set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
22set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
23if(APPLE)
24 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
25endif()
26set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
27set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
28set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
29set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
30set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
31set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
32set(BUILD_GL ON CACHE STRING "Build with OpenGL")
33set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
34set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
35set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
36file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
37file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
38file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
39file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
40file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
41file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
42file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
43file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs] ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
44file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
45file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
46file(GLOB SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
47file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
48file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
49set(CLI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/commandline.c)
50set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
51set(VFS_SRC)
52source_group("ARM core" FILES ${ARM_SRC})
53source_group("LR35902 core" FILES ${LR35902_SRC})
54source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${SIO_SRC})
55source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_EXTRA_SRC} ${GBA_RR_SRC})
56source_group("GB board" FILES ${GB_SRC})
57source_group("Utilities" FILES ${UTIL_SRC})
58include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/src)
59
60if(NOT CMAKE_BUILD_TYPE)
61 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
62endif()
63
64include(GNUInstallDirs)
65
66set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
67mark_as_advanced(LIBDIR)
68
69if (BUILD_LIBRETRO)
70 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
71 mark_as_advanced(LIBRETRO_LIBDIR)
72endif()
73
74if (BUILD_OPENEMU)
75 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
76 mark_as_advanced(OE_LIBDIR)
77endif()
78
79
80set(CMAKE_INSTALL_RPATH "${LIBDIR}")
81
82if (NOT DEFINED MANDIR)
83 set(MANDIR ${CMAKE_INSTALL_MANDIR})
84endif()
85
86# Function definitions
87include(FindPkgConfig)
88function(find_feature FEATURE_NAME FEATURE_REQUIRES)
89 if (NOT ${FEATURE_NAME})
90 return()
91 endif()
92 if (DISABLE_DEPS)
93 set(${FEATURE_NAME} OFF PARENT_SCOPE)
94 return()
95 endif()
96 foreach(REQUIRE ${FEATURE_REQUIRES})
97 if(NOT ${REQUIRE}_FOUND)
98 find_package(${REQUIRE} QUIET)
99 if(NOT ${REQUIRE}_FOUND)
100 pkg_search_module(${REQUIRE} ${REQUIRE})
101 if (NOT ${REQUIRE}_FOUND)
102 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
103 set(${FEATURE_NAME} OFF PARENT_SCOPE)
104 return()
105 endif()
106 endif()
107 endif()
108 string(TOUPPER ${REQUIRE} UREQUIRE)
109 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
110 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
111 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
112 if (APPLE)
113 set(IS_FRAMEWORK OFF)
114 set(LIBS)
115 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
116 if(LIB STREQUAL "-framework")
117 set(IS_FRAMEWORK ON)
118 elseif(IS_FRAMEWORK)
119 list(APPEND LIBS "-framework ${LIB}")
120 set(IS_FRAMEWORK OFF)
121 else()
122 list(APPEND LIBS ${LIB})
123 endif()
124 endforeach()
125 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
126 else()
127 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
128 endif()
129 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
130 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
131 endforeach()
132endfunction()
133
134# Version information
135add_custom_target(version-info ALL
136 COMMAND ${CMAKE_COMMAND}
137 -DBINARY_NAME=${BINARY_NAME}
138 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
139 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
140 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
141 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
142
143include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
144configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
145list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
146source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
147
148# Advanced settings
149set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
150set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
151set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
152set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
153mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
154set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
155set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
156
157if(BUILD_PGO AND NOT PGO_STAGE_2)
158 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
159 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
160 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
161elseif(BUILD_PGO AND PGO_STAGE_2)
162 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
163 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
164 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
165endif()
166
167# Platform support
168if(WIN32)
169 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
170 add_definitions(-D_WIN32_WINNT=0x0600)
171 list(APPEND OS_LIB ws2_32 shlwapi)
172 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
173 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
174 source_group("Windows-specific code" FILES ${OS_SRC})
175 if(MSVC)
176 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
177 endif()
178elseif(UNIX)
179 add_definitions(-DUSE_PTHREADS)
180
181 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
182 add_definitions(-D_GNU_SOURCE)
183 endif()
184 if(NOT APPLE AND NOT HAIKU)
185 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
186 endif()
187
188 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
189 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
190 source_group("POSIX-specific code" FILES ${OS_SRC})
191endif()
192
193if(APPLE)
194 add_definitions(-D_DARWIN_C_SOURCE)
195 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
196endif()
197
198if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
199 set(M_LIBRARY m)
200endif()
201list(APPEND OS_LIB ${M_LIBRARY})
202
203if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
204 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
205 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
206endif()
207
208if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
209 if(NOT BUILD_EGL)
210 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
211 endif()
212endif()
213
214if(BUILD_RASPI)
215 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
216endif()
217
218if(BUILD_PANDORA)
219 add_definitions(-DBUILD_PANDORA)
220endif()
221
222if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
223 enable_language(ASM)
224endif()
225
226if(PSP2 OR WII)
227 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
228endif()
229
230if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII OR NOT M_CORE_GBA)
231 set(USE_GDB_STUB OFF)
232endif()
233
234if(WII)
235 add_definitions(-U__STRICT_ANSI__)
236endif()
237
238include(CheckFunctionExists)
239check_function_exists(strdup HAVE_STRDUP)
240check_function_exists(strndup HAVE_STRNDUP)
241check_function_exists(localtime_r HAVE_LOCALTIME_R)
242if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
243 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
244 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
245 # The strtof_l on Linux not actually exposed nor actually strtof_l
246 set(HAVE_STRTOF_L OFF)
247 else()
248 check_function_exists(strtof_l HAVE_STRTOF_L)
249 endif()
250 check_function_exists(newlocale HAVE_NEWLOCALE)
251 check_function_exists(freelocale HAVE_FREELOCALE)
252 check_function_exists(uselocale HAVE_USELOCALE)
253 check_function_exists(setlocale HAVE_SETLOCALE)
254else()
255 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
256 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
257 endif()
258 set(DISABLE_FRONTENDS ON)
259 set(MINIMAL_CORE ON)
260endif()
261
262check_function_exists(chmod HAVE_CHMOD)
263check_function_exists(umask HAVE_UMASK)
264
265set(FUNCTION_DEFINES)
266
267if(HAVE_STRDUP)
268 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
269endif()
270
271if(HAVE_STRNDUP)
272 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
273endif()
274
275if(HAVE_LOCALTIME_R)
276 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
277endif()
278
279if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
280 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
281 if (HAVE_STRTOF_L)
282 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
283 endif()
284 if (HAVE_SNPRINTF_L)
285 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
286 endif()
287endif()
288
289if(HAVE_SETLOCALE)
290 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
291endif()
292
293if(HAVE_CHMOD)
294 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
295endif()
296
297if(HAVE_UMASK)
298 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
299endif()
300
301# Feature dependencies
302set(FEATURES)
303if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
304 set(LIBEDIT_LIBRARIES -ledit)
305 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
306 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
307 endif()
308else()
309 find_feature(USE_CLI_DEBUGGER "libedit")
310endif()
311if(BUILD_GL)
312 find_package(OpenGL QUIET)
313 if(NOT OPENGL_FOUND)
314 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
315 endif()
316endif()
317if(NOT BUILD_GL)
318 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
319endif()
320if(BUILD_GLES2 AND NOT BUILD_RASPI)
321 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
322 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
323 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
324 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
325 endif()
326endif()
327if(NOT BUILD_GLES2)
328 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
329endif()
330set(WANT_ZLIB ${USE_ZLIB})
331set(WANT_PNG ${USE_PNG})
332set(WANT_LIBZIP ${USE_LIBZIP})
333
334find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
335find_feature(USE_ZLIB "ZLIB")
336find_feature(USE_MINIZIP "minizip")
337find_feature(USE_PNG "PNG")
338find_feature(USE_LIBZIP "libzip")
339find_feature(USE_MAGICK "MagickWand")
340find_feature(USE_EPOXY "epoxy")
341
342# Features
343set(DEBUGGER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c)
344set(FEATURE_SRC)
345set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
346
347if(DISABLE_DEPS)
348 set(USE_GDB_STUB OFF)
349endif()
350
351if(USE_CLI_DEBUGGER)
352 list(APPEND FEATURES CLI_DEBUGGER)
353 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
354 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c)
355 if(M_CORE_GBA)
356 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c)
357 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/cli.c)
358 endif()
359 if(M_CORE_GB)
360 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c)
361 endif()
362 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
363 link_directories(${LIBEDIT_LIBRARY_DIRS})
364 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
365 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
366else()
367 set(DEBUGGER_LIB "")
368endif()
369
370if(USE_GDB_STUB)
371 list(APPEND FEATURES GDB_STUB)
372 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
373endif()
374source_group("Debugger" FILES ${DEBUGGER_SRC})
375
376if(USE_FFMPEG)
377 list(APPEND FEATURES FFMPEG)
378 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
379 if(NOT LIBSWRESAMPLE_FOUND)
380 list(APPEND FEATURES LIBAV)
381 endif()
382 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
383 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
384 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
385 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
386 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
387 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
388 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
389 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
390 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
391 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
392 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
393 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
394 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
395 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
396 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
397 if(APPLE)
398 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
399 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
400 endif()
401endif()
402
403list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
404
405if(USE_MAGICK)
406 list(APPEND FEATURES MAGICK)
407 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
408 link_directories(${MAGICKWAND_LIBRARY_DIRS})
409 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
410 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
411 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
412 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
413 set(MAGICKWAND_DEB_VERSION "5")
414 else()
415 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
416 endif()
417 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
418endif()
419
420if(WANT_ZLIB AND NOT USE_ZLIB)
421 set(SKIP_INSTALL_ALL ON)
422 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
423 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
424 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
425 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
426 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
427 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
428 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
429 set(ZLIB_LIBRARY zlibstatic)
430 list(APPEND DEPENDENCY_LIB zlibstatic)
431 set(USE_ZLIB ON)
432endif()
433
434if(USE_ZLIB)
435 list(APPEND FEATURES ZLIB)
436 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
437 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
438 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
439endif()
440
441if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
442 set(PNG_STATIC ON CACHE BOOL "" FORCE)
443 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
444 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
445 set(SKIP_INSTALL_ALL ON)
446 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
447 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
448 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
449 list(APPEND DEPENDENCY_LIB png16_static)
450 set(USE_PNG ON)
451endif()
452
453if(USE_PNG)
454 list(APPEND FEATURES PNG)
455 include_directories(AFTER ${PNG_INCLUDE_DIRS})
456 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
457 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0")
458endif()
459
460if(USE_LIBZIP)
461 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
462 link_directories(${LIBZIP_LIBRARY_DIRS})
463 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
464 list(APPEND FEATURES LIBZIP)
465 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
466 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
467 if (LIBZIP_VERSION_MAJOR LESS 1)
468 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
469 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
470 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
471 else()
472 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
473 endif()
474elseif(USE_MINIZIP)
475 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
476 link_directories(${MINIZIP_LIBRARY_DIRS})
477 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
478 list(APPEND FEATURES MINIZIP)
479 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
480 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
481elseif(USE_ZLIB)
482 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
483 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
484 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
485 set_source_files_properties(
486 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
487 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
488 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
489endif()
490
491if (USE_LZMA)
492 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
493 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
494 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
495 set(LZMA_SRC
496 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
497 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
498 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
499 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
500 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
501 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
502 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
503 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
504 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
505 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
506 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
507 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
508 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
509 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
510 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
511 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
512 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
513 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
514 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
515 list(APPEND VFS_SRC ${LZMA_SRC})
516 list(APPEND FEATURES LZMA)
517endif()
518
519if(USE_EPOXY)
520 add_definitions(-DBUILD_GL -DBUILD_GLES2)
521 list(APPEND FEATURES EPOXY)
522 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
523 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
524 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
525endif()
526
527
528set(FEATURE_DEFINES)
529foreach(FEATURE IN LISTS FEATURES)
530 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
531endforeach()
532
533set(CORE_SRC)
534if(M_CORE_GB)
535 add_definitions(-DM_CORE_GB)
536 list(APPEND CORE_SRC
537 ${LR35902_SRC}
538 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
539 ${GB_SRC}
540 ${GB_RENDERER_SRC})
541endif()
542
543if(M_CORE_GBA)
544 add_definitions(-DM_CORE_GBA)
545 list(APPEND CORE_SRC
546 ${ARM_SRC}
547 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
548 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
549 ${GBA_SRC}
550 ${GBA_CHEATS_SRC}
551 ${GBA_RENDERER_SRC})
552 if(NOT M_CORE_GB)
553 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
554 endif()
555endif()
556
557source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
558source_group("Extra features" FILES ${FEATURE_SRC})
559source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
560
561# Platform binaries
562if(3DS)
563 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
564endif()
565
566if(WII)
567 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
568endif()
569
570if(PSP2)
571 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
572endif()
573
574# Binaries
575list(APPEND CORE_SRC
576 ${UTIL_SRC}
577 ${CORE_VFS_SRC}
578 ${DEBUGGER_SRC}
579 ${OS_SRC}
580 ${THIRD_PARTY_SRC})
581
582set(SRC ${CORE_SRC} ${VFS_SRC})
583if(NOT MINIMAL_CORE)
584 if(M_CORE_GBA)
585 list(APPEND SRC
586 ${GBA_RR_SRC}
587 ${GBA_EXTRA_SRC}
588 ${SIO_SRC})
589 endif()
590 list(APPEND SRC
591 ${FEATURE_SRC}
592 ${CLI_SRC})
593endif()
594
595if(NOT SKIP_LIBRARY)
596 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
597 set(BUILD_SHARED ON)
598 endif()
599
600 if(BUILD_SHARED)
601 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
602 if(BUILD_STATIC)
603 add_library(${BINARY_NAME}-static STATIC ${SRC})
604 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
605 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
606 add_dependencies(${BINARY_NAME}-static version-info)
607 endif()
608 else()
609 add_library(${BINARY_NAME} STATIC ${SRC})
610 endif()
611
612 add_dependencies(${BINARY_NAME} version-info)
613 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
614
615 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
616 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
617 if(UNIX AND NOT APPLE)
618 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
619 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
620 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
621 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
622 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
623 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
624 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
625 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
626 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
627 endif()
628else()
629 set(BUILD_SHARED OFF)
630 set(BUILD_STATIC OFF)
631 find_library(${BINARY_NAME} ${BINARY_NAME})
632 if(NOT ${BINARY_NAME}_FOUND)
633 set(DISABLE_FRONTENDS ON)
634 set(BUILD_PERF OFF)
635 set(BUILD_TEST OFF)
636 endif()
637endif()
638
639if(BUILD_GL)
640 add_definitions(-DBUILD_GL)
641endif()
642
643if(BUILD_GLES2)
644 add_definitions(-DBUILD_GLES2)
645endif()
646
647if(DISABLE_FRONTENDS)
648 set(BUILD_SDL OFF)
649 set(BUILD_QT OFF)
650endif()
651
652if(BUILD_LIBRETRO)
653 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
654 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
655 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
656 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
657 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
658endif()
659
660if(BUILD_OPENEMU)
661 find_library(FOUNDATION Foundation)
662 find_library(OPENEMUBASE OpenEmuBase)
663 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
664 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
665 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
666 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
667 BUNDLE TRUE
668 BUNDLE_EXTENSION oecoreplugin
669 OUTPUT_NAME ${PROJECT_NAME}
670 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
671 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
672 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
673endif()
674
675if(BUILD_SDL)
676 add_definitions(-DBUILD_SDL)
677 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
678endif()
679
680if(BUILD_QT)
681 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
682endif()
683
684if(BUILD_PERF)
685 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c ${CLI_SRC})
686 if(UNIX AND NOT APPLE)
687 list(APPEND PERF_LIB rt)
688 endif()
689
690 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
691 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
692 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
693 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
694 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
695endif()
696
697if(BUILD_TEST)
698 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
699 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
700 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
701 install(TARGETS ${BINARY_NAME}-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
702endif()
703
704if(BUILD_EXAMPLE)
705 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
706 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
707 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
708
709 if(BUILD_SDL)
710 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
711 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
712 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
713 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
714 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src")
715 endif()
716endif()
717
718# Packaging
719set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
720set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
721set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
722set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
723set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
724set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
725
726set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
727set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
728set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
729set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
730set(CPACK_DEBIAN_PACKAGE_SECTION "games")
731
732SET(CPACK_DEB_COMPONENT_INSTALL ON)
733
734set(CPACK_STRIP_FILES ${BINARY_NAME})
735
736install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
737
738include(CPack)
739
740# Summaries
741set(SUMMARY_GL_LIST)
742if(USE_EPOXY)
743 set(SUMMARY_GL_LIST "libepoxy")
744else()
745 if(BUILD_GL)
746 list(APPEND SUMMARY_GL_LIST "OpenGL")
747 endif()
748 if(BUILD_GLES2)
749 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
750 endif()
751endif()
752if(NOT SUMMARY_GL_LIST)
753 set(SUMMARY_GL OFF)
754else()
755 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
756endif()
757if(USE_LIBZIP)
758 set(SUMMARY_ZIP libzip)
759elseif(USE_MINIZIP)
760 set(SUMMARY_ZIP "minizip (external)")
761elseif(USE_ZLIB)
762 set(SUMMARY_ZIP "minizip (included)")
763else()
764 set(SUMMARY_ZIP OFF)
765endif()
766
767if(NOT QUIET)
768 message(STATUS "Platforms:")
769 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
770 message(STATUS " Game Boy: ${M_CORE_GB}")
771 message(STATUS "Features:")
772 message(STATUS " CLI debugger: ${USE_CLI_DEBUGGER}")
773 message(STATUS " GDB stub: ${USE_GDB_STUB}")
774 message(STATUS " Video recording: ${USE_FFMPEG}")
775 message(STATUS " GIF recording: ${USE_MAGICK}")
776 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
777 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
778 message(STATUS " 7-Zip support: ${USE_LZMA}")
779 message(STATUS " OpenGL support: ${SUMMARY_GL}")
780 message(STATUS "Frontends:")
781 message(STATUS " Qt: ${BUILD_QT}")
782 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
783 message(STATUS " Profiling: ${BUILD_PERF}")
784 message(STATUS " Test harness: ${BUILD_TEST}")
785 message(STATUS " Examples: ${BUILD_EXAMPLE}")
786 message(STATUS "Cores:")
787 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
788 if(APPLE)
789 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
790 endif()
791 message(STATUS "Libraries:")
792 message(STATUS " Static: ${BUILD_STATIC}")
793 message(STATUS " Shared: ${BUILD_SHARED}")
794endif()