1cmake_minimum_required(VERSION 2.6)
  2project(mGBA C)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -std=c99")
  6else()
  7	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
  8endif()
  9set(USE_CLI_DEBUGGER ON CACHE BOOL "Whether or not to enable the CLI-mode ARM debugger")
 10set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 11set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 12set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 13set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable ZIP support")
 14set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 15set(USE_BLIP ON CACHE BOOL "Whether or not to enable blip_buf support")
 16set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 17set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 18set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 19set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 20set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 21set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 22set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 23set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 24file(GLOB ARM_SRC ${CMAKE_SOURCE_DIR}/src/arm/*.c)
 25file(GLOB GBA_SRC ${CMAKE_SOURCE_DIR}/src/gba/*.c)
 26file(GLOB GBA_CHEATS_SRC ${CMAKE_SOURCE_DIR}/src/gba/cheats/*.c)
 27file(GLOB GBA_RR_SRC ${CMAKE_SOURCE_DIR}/src/gba/rr/*.c)
 28file(GLOB GBA_SV_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/*.c)
 29file(GLOB UTIL_SRC ${CMAKE_SOURCE_DIR}/src/util/*.[cSs])
 30file(GLOB RENDERER_SRC ${CMAKE_SOURCE_DIR}/src/gba/renderers/*.c)
 31file(GLOB SIO_SRC ${CMAKE_SOURCE_DIR}/src/gba/sio/lockstep.c)
 32file(GLOB THIRD_PARTY_SRC ${CMAKE_SOURCE_DIR}/src/third-party/inih/*.c)
 33list(APPEND UTIL_SRC ${CMAKE_SOURCE_DIR}/src/platform/commandline.c)
 34set(VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-mem.c)
 35source_group("ARM core" FILES ${ARM_SRC})
 36source_group("GBA board" FILES ${GBA_SRC} ${RENDERER_SRC} ${SIO_SRC})
 37source_group("GBA supervisor" FILES ${GBA_CHEATS_SRC} ${GBA_SV_SRC} ${GBA_RR_SRC})
 38source_group("Utilities" FILES ${UTIL_SRC})
 39include_directories(${CMAKE_SOURCE_DIR}/src/arm)
 40include_directories(${CMAKE_SOURCE_DIR}/src)
 41
 42if(NOT CMAKE_BUILD_TYPE)
 43	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 44endif()
 45
 46set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 47
 48include(GNUInstallDirs)
 49
 50# Function definitions
 51include(FindPkgConfig)
 52function(find_feature FEATURE_NAME FEATURE_REQUIRES)
 53	if (NOT ${FEATURE_NAME})
 54		return()
 55	endif()
 56	foreach(REQUIRE ${FEATURE_REQUIRES})
 57		if(NOT ${REQUIRE}_FOUND)
 58			find_package(${REQUIRE} QUIET)
 59			if(NOT ${REQUIRE}_FOUND)
 60				pkg_search_module(${REQUIRE} ${REQUIRE})
 61				if (NOT ${REQUIRE}_FOUND)
 62					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
 63					set(${FEATURE_NAME} OFF PARENT_SCOPE)
 64					return()
 65				endif()
 66			endif()
 67		endif()
 68		string(TOUPPER ${REQUIRE} UREQUIRE)
 69		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
 70		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
 71		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
 72		set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
 73		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
 74		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
 75	endforeach()
 76endfunction()
 77
 78# Version information
 79add_custom_target(version-info ALL ${CMAKE_COMMAND} -E touch ${CMAKE_SOURCE_DIR}/src/util/version.c.in
 80	COMMAND ${CMAKE_COMMAND}
 81	-DBINARY_NAME=${BINARY_NAME}
 82	-DCONFIG_FILE=${CMAKE_SOURCE_DIR}/src/util/version.c.in
 83	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
 84	-P ${CMAKE_SOURCE_DIR}/version.cmake
 85	WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
 86
 87include(${CMAKE_SOURCE_DIR}/version.cmake)
 88configure_file(${CMAKE_SOURCE_DIR}/src/util/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
 89list(APPEND UTIL_SRC ${CMAKE_BINARY_DIR}/version.c)
 90source_group("Generated sources" FILES ${CMAKE_BINARY_DIR}/version.c)
 91
 92# Advanced settings
 93set(BUILD_LTO ON CACHE BOOL "Build with link-time optimization")
 94set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
 95set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
 96set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
 97mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
 98set(PGO_PRE_FLAGS "-pg -fprofile-generate=${PGO_DIR} -fprofile-arcs")
 99set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
100
101if(BUILD_PGO AND NOT PGO_STAGE_2)
102	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
103	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
104	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
105elseif(BUILD_PGO AND PGO_STAGE_2)
106	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
107	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
108	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
109endif()
110
111# Feature dependencies
112set(FEATURES)
113if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
114	set(LIBEDIT_LIBRARIES -ledit)
115	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
116		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
117	endif()
118else()
119	find_feature(USE_CLI_DEBUGGER "libedit")
120endif()
121if(BUILD_GL)
122	find_package(OpenGL QUIET)
123	if(NOT OPENGL_FOUND)
124		set(BUILD_GL OFF)
125	endif()
126endif()
127find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
128find_feature(USE_PNG "ZLIB;PNG")
129find_feature(USE_LIBZIP "libzip")
130find_feature(USE_MAGICK "MagickWand")
131
132# Platform support
133if(WIN32)
134	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
135	add_definitions(-D_WIN32_WINNT=0x0600)
136	list(APPEND OS_LIB ws2_32 shlwapi)
137	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
138	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/windows/*.c)
139	source_group("Windows-specific code" FILES ${OS_SRC})
140elseif(UNIX)
141	add_definitions(-DUSE_PTHREADS)
142
143	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
144		add_definitions(-D_GNU_SOURCE)
145	endif()
146	if(NOT APPLE AND NOT HAIKU)
147		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
148	endif()
149
150	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
151	file(GLOB OS_SRC ${CMAKE_SOURCE_DIR}/src/platform/posix/*.c)
152	source_group("POSIX-specific code" FILES ${OS_SRC})
153endif()
154
155if(APPLE)
156	add_definitions(-D_DARWIN_C_SOURCE)
157	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
158endif()
159
160if(NOT HAIKU AND NOT MSVC)
161	list(APPEND OS_LIB m)
162endif()
163
164if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
165	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
166	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
167endif()
168
169if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
170	if(NOT BUILD_EGL)
171		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
172	endif()
173endif()
174
175if(BUILD_PANDORA)
176	add_definitions(-DBUILD_PANDORA)
177endif()
178
179if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
180	enable_language(ASM)
181endif()
182
183include(CheckFunctionExists)
184check_function_exists(strdup HAVE_STRDUP)
185check_function_exists(strndup HAVE_STRNDUP)
186check_function_exists(snprintf_l HAVE_SNPRINTF_L)
187if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
188	# The strtof_l on Linux not actually exposed nor actually strtof_l
189	set(HAVE_STRTOF_L OFF)
190else()
191	check_function_exists(strtof_l HAVE_STRTOF_L)
192endif()
193check_function_exists(newlocale HAVE_NEWLOCALE)
194check_function_exists(freelocale HAVE_FREELOCALE)
195check_function_exists(uselocale HAVE_USELOCALE)
196check_function_exists(setlocale HAVE_SETLOCALE)
197
198if(HAVE_STRDUP)
199	add_definitions(-DHAVE_STRDUP)
200endif()
201
202if(HAVE_STRNDUP)
203	add_definitions(-DHAVE_STRNDUP)
204endif()
205
206if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE)
207	add_definitions(-DHAVE_LOCALE)
208	if (HAVE_STRTOF_L)
209		add_definitions(-DHAVE_STRTOF_L)
210	endif()
211	if (HAVE_SNPRINTF_L)
212		add_definitions(-DHAVE_SNPRINTF_L)
213	endif()
214endif()
215
216if(HAVE_SETLOCALE)
217	add_definitions(-DHAVE_SETLOCALE)
218endif()
219
220# Features
221set(DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/debugger.c ${CMAKE_SOURCE_DIR}/src/debugger/memory-debugger.c)
222set(FEATURE_SRC)
223set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
224
225if(USE_CLI_DEBUGGER)
226	list(APPEND FEATURES CLI_DEBUGGER)
227	list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/cli-debugger.c)
228	list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/debugger/parser.c)
229	list(APPEND FEATURE_SRC ${CMAKE_SOURCE_DIR}/src/gba/supervisor/cli.c)
230	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
231	link_directories(${LIBEDIT_LIBRARY_DIRS})
232	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
233	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
234else()
235	set(DEBUGGER_LIB "")
236endif()
237
238if(USE_GDB_STUB)
239	list(APPEND FEATURES GDB_STUB)
240	list(APPEND DEBUGGER_SRC ${CMAKE_SOURCE_DIR}/src/debugger/gdb-stub.c)
241endif()
242source_group("ARM debugger" FILES ${DEBUGGER_SRC})
243
244if(USE_FFMPEG)
245	list(APPEND FEATURES FFMPEG)
246	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
247	if(NOT LIBSWRESAMPLE_FOUND)
248		list(APPEND FEATURES LIBAV)
249	endif()
250	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
251	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
252	list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/ffmpeg/ffmpeg-encoder.c")
253	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
254	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
255	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
256	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
257	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
258	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
259	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR},libavformat${LIBAVFORMAT_VERSION_MAJOR},libavresample${LIBAVRESAMPLE_VERSION_MAJOR},libavutil${LIBAVUTIL_VERSION_MAJOR},libswscale${LIBSWSCALE_VERSION_MAJOR}")
260	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra")
261	if(APPLE)
262		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
263		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
264	endif()
265endif()
266
267if(USE_BLIP)
268	list(APPEND THIRD_PARTY_SRC "${CMAKE_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
269	add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_BLIP_BUF)
270else()
271	add_definitions(-DRESAMPLE_LIBRARY=RESAMPLE_NN)
272endif()
273
274if(USE_MAGICK)
275	list(APPEND FEATURES MAGICK)
276	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
277	link_directories(${MAGICKWAND_LIBRARY_DIRS})
278	list(APPEND FEATURE_SRC "${CMAKE_SOURCE_DIR}/src/platform/imagemagick/imagemagick-gif-encoder.c")
279	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
280	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
281	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
282		set(MAGICKWAND_DEB_VERSION "5")
283	else()
284		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
285	endif()
286	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
287endif()
288
289if(USE_PNG)
290	list(APPEND FEATURES PNG)
291	include_directories(AFTER ${PNG_INCLUDE_DIRS})
292	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
293	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng12-0,zlib1g")
294endif()
295
296if(USE_LIBZIP)
297	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
298	link_directories(${LIBZIP_LIBRARY_DIRS})
299	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
300	list(APPEND FEATURES LIBZIP)
301	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
302	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
303endif()
304
305if (USE_LZMA)
306	include_directories(AFTER ${CMAKE_SOURCE_DIR}/third-party/lzma)
307	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
308	list(APPEND VFS_SRC ${CMAKE_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
309	set(LZMA_SRC
310		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
311		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
312		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
313		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
314		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
315		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
316		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zDec.c
317		${CMAKE_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
318		${CMAKE_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
319		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
320		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra.c
321		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bra86.c
322		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
323		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
324		${CMAKE_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
325		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zFile.c
326		${CMAKE_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
327	list(APPEND FEATURE_SRC ${LZMA_SRC})
328	list(APPEND FEATURES LZMA)
329endif()
330
331set(FEATURE_DEFINES)
332foreach(FEATURE IN LISTS FEATURES)
333	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
334endforeach()
335
336source_group("Virtual files" FILES ${VFS_SRC})
337source_group("Extra features" FILES ${FEATURE_SRC})
338source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
339
340# Binaries
341set(CORE_SRC
342	${ARM_SRC}
343	${GBA_SRC}
344	${GBA_CHEATS_SRC}
345	${GBA_RR_SRC}
346	${GBA_SV_SRC}
347	${DEBUGGER_SRC}
348	${RENDERER_SRC}
349	${SIO_SRC}
350	${UTIL_SRC}
351	${VFS_SRC}
352	${OS_SRC}
353	${THIRD_PARTY_SRC})
354
355set(SRC
356	${CORE_SRC}
357	${FEATURE_SRC})
358
359if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
360	set(BUILD_SHARED ON)
361endif()
362
363if(BUILD_SHARED)
364	add_library(${BINARY_NAME} SHARED ${SRC})
365	if(BUILD_STATIC)
366		add_library(${BINARY_NAME}-static STATIC ${SRC})
367		set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
368		install(TARGETS ${BINARY_NAME}-static DESTINATION lib COMPONENT lib${BINARY_NAME})
369		add_dependencies(${BINARY_NAME}-static version-info)
370	endif()
371else()
372	add_library(${BINARY_NAME} STATIC ${SRC})
373endif()
374
375add_dependencies(${BINARY_NAME} version-info)
376
377target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
378install(TARGETS ${BINARY_NAME} DESTINATION lib COMPONENT lib${BINARY_NAME})
379if(UNIX AND NOT APPLE)
380	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
381	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
382	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
383	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
384	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
385	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
386	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
387	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
388	install(FILES ${CMAKE_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
389endif()
390set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${FEATURE_DEFINES}")
391
392if(BUILD_GL)
393	add_definitions(-DBUILD_GL)
394endif()
395
396if(BUILD_LIBRETRO)
397	file(GLOB RETRO_SRC ${CMAKE_SOURCE_DIR}/src/platform/libretro/*.c)
398	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
399	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5")
400	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
401endif()
402
403if(BUILD_SDL)
404	add_definitions(-DBUILD_SDL)
405	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/sdl ${CMAKE_BINARY_DIR}/sdl)
406endif()
407
408if(BUILD_QT)
409	add_subdirectory(${CMAKE_SOURCE_DIR}/src/platform/qt ${CMAKE_BINARY_DIR}/qt)
410endif()
411
412if(BUILD_PERF)
413	set(PERF_SRC ${CMAKE_SOURCE_DIR}/src/platform/perf-main.c)
414	if(UNIX AND NOT APPLE)
415		list(APPEND PERF_LIB rt)
416	endif()
417
418	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
419	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB})
420	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
421	install(FILES ${CMAKE_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
422endif()
423
424# Packaging
425set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
426set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
427set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
428set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
429set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_SOURCE_DIR}/LICENSE)
430set(CPACK_RESOURCE_FILE_README ${CMAKE_SOURCE_DIR}/README.md)
431
432set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
433set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
434set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
435set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
436set(CPACK_DEBIAN_PACKAGE_SECTION "games")
437
438SET(CPACK_DEB_COMPONENT_INSTALL ON)
439
440set(CPACK_STRIP_FILES ${BINARY_NAME})
441
442install(FILES ${CMAKE_SOURCE_DIR}/README.md ${CMAKE_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
443
444include(CPack)
445
446# Summaries
447message(STATUS "Feature summary:")
448message(STATUS "	CLI debugger: ${USE_CLI_DEBUGGER}")
449message(STATUS "	GDB stub: ${USE_GDB_STUB}")
450message(STATUS "	Video recording: ${USE_FFMPEG}")
451message(STATUS "	GIF recording: ${USE_MAGICK}")
452message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
453message(STATUS "	ZIP support: ${USE_LIBZIP}")
454message(STATUS "	7-Zip support: ${USE_LZMA}")
455message(STATUS "	Better audio resampling: ${USE_BLIP}")
456message(STATUS "Frontend summary:")
457message(STATUS "	Qt: ${BUILD_QT}")
458message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
459message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
460message(STATUS "	Profiling: ${BUILD_PERF}")
461message(STATUS "Library summary:")
462message(STATUS "	Static: ${BUILD_STATIC}")
463message(STATUS "	Shared: ${BUILD_SHARED}")