1cmake_minimum_required(VERSION 2.8.11)
  2project(mGBA)
  3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
  4if(NOT MSVC)
  5	set(GCC_STD "c99")
  6        if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_COMPILER_VERSION VERSION_LESS "4.3")
  7		set(GCC_STD "gnu99")
  8	endif()
  9	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=${GCC_STD}")
 10else()
 11	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
 12endif()
 13set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
 14set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
 15set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
 16set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
 17set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
 18set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
 19set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
 20set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
 21set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
 22set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
 23set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
 24set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
 25set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
 26set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
 27set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
 28set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
 29if(APPLE)
 30	set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
 31endif()
 32set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
 33set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
 34set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
 35set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
 36set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
 37set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
 38set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
 39set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
 40set(BUILD_GL ON CACHE STRING "Build with OpenGL")
 41set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
 42set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
 43set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
 44file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
 45file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
 46file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
 47file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
 48file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
 49file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
 50file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
 51file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
 52file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
 53file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
 54file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
 55file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
 56file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
 57file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
 58file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
 59file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
 60file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/lockstep.c)
 61file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
 62file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/lockstep.c)
 63file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
 64file(GLOB GB_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/*.c)
 65file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
 66file(GLOB EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/*.c)
 67set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fifo.c)
 68set(VFS_SRC)
 69source_group("ARM core" FILES ${ARM_SRC})
 70source_group("LR35902 core" FILES ${LR35902_SRC})
 71source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
 72source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
 73source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
 74source_group("Utilities" FILES ${UTIL_SRC})
 75include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
 76
 77if(NOT CMAKE_BUILD_TYPE)
 78	set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
 79endif()
 80
 81include(GNUInstallDirs)
 82
 83set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
 84mark_as_advanced(LIBDIR)
 85
 86if (BUILD_LIBRETRO)
 87	set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
 88	mark_as_advanced(LIBRETRO_LIBDIR)
 89endif()
 90
 91if (BUILD_OPENEMU)
 92	set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
 93	mark_as_advanced(OE_LIBDIR)
 94endif()
 95
 96
 97set(CMAKE_INSTALL_RPATH "${LIBDIR}")
 98
 99if (NOT DEFINED MANDIR)
100	set(MANDIR ${CMAKE_INSTALL_MANDIR})
101endif()
102
103# Function definitions
104include(FindPkgConfig)
105function(find_feature FEATURE_NAME FEATURE_REQUIRES)
106	if (NOT ${FEATURE_NAME})
107		return()
108	endif()
109	if (DISABLE_DEPS)
110		set(${FEATURE_NAME} OFF PARENT_SCOPE)
111		return()
112	endif()
113	foreach(REQUIRE ${FEATURE_REQUIRES})
114		if(NOT ${REQUIRE}_FOUND)
115			find_package(${REQUIRE} QUIET)
116			if(NOT ${REQUIRE}_FOUND)
117				pkg_search_module(${REQUIRE} ${REQUIRE})
118				if (NOT ${REQUIRE}_FOUND)
119					message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
120					set(${FEATURE_NAME} OFF PARENT_SCOPE)
121					return()
122				endif()
123			endif()
124		endif()
125		string(TOUPPER ${REQUIRE} UREQUIRE)
126		set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
127		set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
128		set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
129		set(${UREQUIRE}_VERSION_STRING ${${REQUIRE}_VERSION_STRING} PARENT_SCOPE)
130		if (APPLE)
131			set(IS_FRAMEWORK OFF)
132			set(LIBS)
133			foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
134				if(LIB STREQUAL "-framework")
135					set(IS_FRAMEWORK ON)
136				elseif(IS_FRAMEWORK)
137					list(APPEND LIBS "-framework ${LIB}")
138					set(IS_FRAMEWORK OFF)
139				else()
140					list(APPEND LIBS ${LIB})
141				endif()
142			endforeach()
143			set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
144		else()
145			set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
146		endif()
147		set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
148		set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
149	endforeach()
150endfunction()
151
152# Version information
153add_custom_target(version-info ALL
154	COMMAND ${CMAKE_COMMAND}
155	-DBINARY_NAME=${BINARY_NAME}
156	-DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
157	-DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
158	-P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
159	WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
160
161include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
162configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
163
164list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
165source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
166
167# Advanced settings
168if(NOT DEFINED 3DS)
169	# LTO appears to make 3DS binary slower
170	set(DEFAULT_LTO ON)
171else()
172	set(DEFAULT_LTO OFF)
173endif()
174
175set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
176set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
177set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
178set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
179mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
180set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
181set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
182
183if(BUILD_PGO AND NOT PGO_STAGE_2)
184	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
185	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
186	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
187elseif(BUILD_PGO AND PGO_STAGE_2)
188	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
189	set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
190	set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
191endif()
192
193# Platform support
194if(WIN32)
195	set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
196	add_definitions(-D_WIN32_WINNT=0x0600)
197	list(APPEND OS_LIB ws2_32 shlwapi)
198	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
199	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
200	source_group("Windows-specific code" FILES ${OS_SRC})
201	if(MSVC)
202		add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
203		set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
204	endif()
205elseif(UNIX)
206	set(USE_PTHREADS ON)
207	add_definitions(-DUSE_PTHREADS)
208
209	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
210		add_definitions(-D_GNU_SOURCE)
211	endif()
212	if(NOT APPLE AND NOT HAIKU)
213		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
214	endif()
215
216	list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
217	file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
218	source_group("POSIX-specific code" FILES ${OS_SRC})
219endif()
220
221if(APPLE)
222	add_definitions(-D_DARWIN_C_SOURCE)
223	if(CMAKE_SYSTEM_VERSION VERSION_GREATER "10.5.8")
224		set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
225	endif()
226endif()
227
228if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
229	set(M_LIBRARY m)
230endif()
231list(APPEND OS_LIB ${M_LIBRARY})
232
233if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
234	set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
235	set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
236endif()
237
238if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
239	if(NOT BUILD_EGL)
240		add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
241	endif()
242endif()
243
244if(BUILD_RASPI)
245	set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
246endif()
247
248if(BUILD_PANDORA)
249	add_definitions(-DBUILD_PANDORA)
250endif()
251
252if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
253	enable_language(ASM)
254endif()
255
256if(PSP2 OR WII)
257	set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
258endif()
259
260if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
261	set(USE_DEBUGGERS OFF)
262	set(USE_SQLITE3 OFF)
263endif()
264
265if(NOT M_CORE_GBA)
266	set(USE_GDB_STUB OFF)
267endif()
268
269if(NOT USE_DEBUGGERS)
270	set(USE_EDITLINE OFF)
271	set(USE_GDB_STUB OFF)
272endif()
273
274if(WII)
275	add_definitions(-U__STRICT_ANSI__)
276endif()
277
278if(DEFINED 3DS)
279	add_definitions(-D_GNU_SOURCE)
280endif()
281
282include(CheckFunctionExists)
283check_function_exists(strdup HAVE_STRDUP)
284check_function_exists(strndup HAVE_STRNDUP)
285if(NOT DEFINED PSP2)
286	check_function_exists(localtime_r HAVE_LOCALTIME_R)
287endif()
288if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
289	check_function_exists(snprintf_l HAVE_SNPRINTF_L)
290	if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
291		# The strtof_l on Linux not actually exposed nor actually strtof_l
292		set(HAVE_STRTOF_L OFF)
293	else()
294		check_function_exists(strtof_l HAVE_STRTOF_L)
295	endif()
296	check_function_exists(newlocale HAVE_NEWLOCALE)
297	check_function_exists(freelocale HAVE_FREELOCALE)
298	check_function_exists(uselocale HAVE_USELOCALE)
299	check_function_exists(setlocale HAVE_SETLOCALE)
300else()
301	if(DEFINED 3DS)
302		check_function_exists(snprintf_l HAVE_SNPRINTF_L)
303		check_function_exists(strtof_l HAVE_STRTOF_L)
304		check_function_exists(newlocale HAVE_NEWLOCALE)
305		check_function_exists(freelocale HAVE_FREELOCALE)
306		check_function_exists(uselocale HAVE_USELOCALE)
307		check_function_exists(setlocale HAVE_SETLOCALE)
308	endif()
309	if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
310		set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
311	endif()
312	set(DISABLE_FRONTENDS ON)
313	set(MINIMAL_CORE ON)
314	set(ENABLE_EXTRA ON)
315endif()
316
317check_function_exists(chmod HAVE_CHMOD)
318check_function_exists(umask HAVE_UMASK)
319
320set(FUNCTION_DEFINES)
321
322if(HAVE_STRDUP)
323	list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
324endif()
325
326if(HAVE_STRNDUP)
327	list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
328endif()
329
330if(HAVE_LOCALTIME_R)
331	list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
332endif()
333
334if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE OR DEFINED 3DS)
335	list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
336	if (HAVE_STRTOF_L)
337		list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
338	endif()
339	if (HAVE_SNPRINTF_L)
340		list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
341	endif()
342endif()
343
344if(HAVE_SETLOCALE)
345	list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
346endif()
347
348if(HAVE_CHMOD)
349	list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
350endif()
351
352if(HAVE_UMASK)
353	list(APPEND FUNCTION_DEFINES HAVE_UMASK)
354endif()
355
356# Feature dependencies
357set(FEATURE_DEFINES)
358set(FEATURES)
359if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
360	set(LIBEDIT_LIBRARIES -ledit)
361	if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
362		list(APPEND LIBEDIT_LIBRARIES -ltermcap)
363	endif()
364else()
365	find_feature(USE_EDITLINE "libedit")
366endif()
367if(BUILD_GL)
368	find_package(OpenGL QUIET)
369	if(NOT OPENGL_FOUND)
370		set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
371	endif()
372endif()
373if(NOT BUILD_GL)
374	set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
375endif()
376if(BUILD_GLES2 AND NOT BUILD_RASPI)
377	find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
378	find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
379	if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
380		set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
381	endif()
382endif()
383if(NOT BUILD_GLES2)
384	set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
385endif()
386set(WANT_ZLIB ${USE_ZLIB})
387set(WANT_PNG ${USE_PNG})
388set(WANT_LIBZIP ${USE_LIBZIP})
389set(WANT_SQLITE3 ${USE_SQLITE3})
390set(USE_CMOCKA ${BUILD_SUITE})
391
392find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
393find_feature(USE_ZLIB "ZLIB")
394find_feature(USE_MINIZIP "minizip")
395find_feature(USE_PNG "PNG")
396find_feature(USE_LIBZIP "libzip")
397find_feature(USE_MAGICK "MagickWand")
398find_feature(USE_EPOXY "epoxy")
399find_feature(USE_CMOCKA "cmocka")
400find_feature(USE_SQLITE3 "sqlite3")
401
402# Features
403set(DEBUGGER_SRC
404	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
405	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
406	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/symbols.c
407	${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
408
409set(FEATURE_SRC)
410set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
411
412if(DISABLE_DEPS)
413	set(USE_GDB_STUB OFF)
414endif()
415
416if(USE_EDITLINE)
417	list(APPEND FEATURES EDITLINE)
418	include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
419	link_directories(${LIBEDIT_LIBRARY_DIRS})
420	set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
421	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
422	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
423else()
424	set(DEBUGGER_LIB "")
425endif()
426
427if(USE_GDB_STUB)
428	list(APPEND FEATURES GDB_STUB)
429	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
430endif()
431source_group("Debugger" FILES ${DEBUGGER_SRC})
432
433if(USE_FFMPEG)
434	list(APPEND FEATURES FFMPEG)
435	pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
436	if(NOT LIBSWRESAMPLE_FOUND)
437		list(APPEND FEATURES LIBAV)
438	endif()
439	include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
440	link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
441	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
442	string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
443	string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
444	string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
445	string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
446	string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
447	list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
448	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
449	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
450	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
451	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
452	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
453	set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
454	if(APPLE)
455		set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
456		set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
457	endif()
458endif()
459
460list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
461
462if(USE_MAGICK)
463	list(APPEND FEATURES MAGICK)
464	include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
465	link_directories(${MAGICKWAND_LIBRARY_DIRS})
466	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
467	list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
468	string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
469	string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
470	if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
471		set(MAGICKWAND_DEB_VERSION "5")
472	elseif(${MagickWand_VERSION} EQUAL "6.9.7")
473		set(MAGICKWAND_DEB_VERSION "-6.q16-3")
474	else()
475		set(MAGICKWAND_DEB_VERSION "-6.q16-2")
476	endif()
477	list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
478
479	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
480endif()
481
482if(WANT_ZLIB AND NOT USE_ZLIB)
483	set(SKIP_INSTALL_ALL ON)
484	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
485	set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
486	set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
487	set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
488	set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
489	set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
490	set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
491	set(ZLIB_LIBRARY zlibstatic)
492	list(APPEND DEPENDENCY_LIB zlibstatic)
493	set(USE_ZLIB ON)
494endif()
495
496if(USE_ZLIB)
497	list(APPEND FEATURES ZLIB)
498	include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
499	list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
500	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
501endif()
502
503if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
504	set(PNG_STATIC ON CACHE BOOL "" FORCE)
505	set(PNG_SHARED OFF CACHE BOOL "" FORCE)
506	set(PNG_TESTS OFF CACHE BOOL "" FORCE)
507	set(SKIP_INSTALL_ALL ON)
508	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
509	set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
510	set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
511	list(APPEND DEPENDENCY_LIB png16_static)
512	set(USE_PNG ON)
513endif()
514
515if(USE_PNG)
516	list(APPEND FEATURES PNG)
517	include_directories(AFTER ${PNG_INCLUDE_DIRS})
518	list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
519	if(PNG_VERSION_STRING)
520		string(REGEX MATCH "^[0-9]+\\.[0-9]+" PNG_VERSION_PARTIAL ${PNG_VERSION_STRING})
521		if(${PNG_VERSION_PARTIAL} STREQUAL "1.6")
522			set(PNG_DEB_VERSION "16-16")
523		else()
524			set(PNG_DEB_VERSION "12-0")
525		endif()
526		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng${PNG_DEB_VERSION}")
527	endif()
528endif()
529
530if(WANT_SQLITE3 AND NOT USE_SQLITE3)
531	list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
532	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
533	set(USE_SQLITE3 ON)
534endif()
535
536if(USE_LIBZIP)
537	include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
538	link_directories(${LIBZIP_LIBRARY_DIRS})
539	list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
540	list(APPEND FEATURES LIBZIP)
541	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
542	string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
543	if (LIBZIP_VERSION_MAJOR LESS 1)
544		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
545	elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
546		set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
547	else()
548		message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
549	endif()
550elseif(USE_MINIZIP)
551	include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
552	link_directories(${MINIZIP_LIBRARY_DIRS})
553	list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
554	list(APPEND FEATURES MINIZIP)
555	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
556	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
557elseif(USE_ZLIB)
558	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
559		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
560		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
561	if(NOT MSVC)
562		set_source_files_properties(
563			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
564			${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
565			PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
566	endif()
567endif()
568
569if (USE_LZMA)
570	include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/third-party/lzma)
571	add_definitions(-D_7ZIP_PPMD_SUPPPORT)
572	list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
573	set(LZMA_SRC
574		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
575		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
576		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
577		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
578		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
579		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
580		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
581		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
582		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
583		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
584		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
585		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
586		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
587		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
588		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
589		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
590		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
591		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
592		${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
593	list(APPEND VFS_SRC ${LZMA_SRC})
594	list(APPEND FEATURES LZMA)
595endif()
596
597if(USE_EPOXY)
598	add_definitions(-DBUILD_GL -DBUILD_GLES2)
599	list(APPEND FEATURES EPOXY)
600	include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
601	set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
602	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
603endif()
604
605if(USE_SQLITE3)
606	list(APPEND FEATURES SQLITE3)
607	include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
608	list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
609	set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
610	list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
611endif()
612
613set(TEST_SRC ${CORE_TEST_SRC})
614if(M_CORE_GB)
615	add_definitions(-DM_CORE_GB)
616	list(APPEND CORE_SRC
617		${LR35902_SRC}
618		${GB_SRC}
619		${GB_RENDERER_SRC})
620	list(APPEND DEBUGGER_SRC
621		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
622		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
623		${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/memory-debugger.c
624		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/cli.c
625		${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/symbols.c)
626	list(APPEND TEST_SRC
627		${LR35902_TEST_SRC}
628		${GB_TEST_SRC})
629endif()
630
631if(M_CORE_GBA)
632	add_definitions(-DM_CORE_GBA)
633	list(APPEND CORE_SRC
634		${ARM_SRC}
635		${GBA_SRC}
636		${GBA_CHEATS_SRC}
637		${GBA_RENDERER_SRC})
638	list(APPEND DEBUGGER_SRC
639		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
640		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
641		${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
642		${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
643	list(APPEND TEST_SRC
644		${ARM_TEST_SRC}
645		${GBA_TEST_SRC})
646	if(NOT M_CORE_GB)
647		list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
648	endif()
649endif()
650
651if(USE_DEBUGGERS)
652	list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
653	list(APPEND FEATURES DEBUGGERS)
654endif()
655
656foreach(FEATURE IN LISTS FEATURES)
657	list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
658endforeach()
659
660source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
661source_group("Extra features" FILES ${FEATURE_SRC})
662source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
663
664# Platform binaries
665if(DEFINED 3DS)
666	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
667endif()
668
669if(DEFINED WII)
670	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
671endif()
672
673if(DEFINED PSP2)
674	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
675endif()
676
677# Binaries
678list(APPEND CORE_SRC
679	${UTIL_SRC}
680	${CORE_VFS_SRC}
681	${OS_SRC}
682	${THIRD_PARTY_SRC})
683list(APPEND TEST_SRC ${UTIL_TEST_SRC})
684
685set(SRC ${CORE_SRC} ${VFS_SRC})
686if(NOT MINIMAL_CORE)
687	set(ENABLE_EXTRA ON)
688	if(M_CORE_GBA)
689		list(APPEND SRC
690			${GBA_SIO_SRC})
691	endif()
692	if(M_CORE_GB)
693		list(APPEND SRC
694			${GB_SIO_SRC})
695	endif()
696	list(APPEND SRC
697		${FEATURE_SRC})
698endif()
699
700if(ENABLE_EXTRA)
701	if(M_CORE_GBA)
702		list(APPEND SRC
703			${GBA_RR_SRC}
704			${GBA_EXTRA_SRC})
705	endif()
706	if(M_CORE_GB)
707		list(APPEND SRC
708			${GB_EXTRA_SRC})
709	endif()
710	list(APPEND SRC
711		${EXTRA_SRC})
712endif()
713
714if(NOT SKIP_LIBRARY)
715	if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
716		set(BUILD_SHARED ON)
717	endif()
718
719	if(BUILD_SHARED)
720		add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
721		if(BUILD_STATIC)
722			add_library(${BINARY_NAME}-static STATIC ${SRC})
723			set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
724			install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
725			add_dependencies(${BINARY_NAME}-static version-info)
726		endif()
727	else()
728		add_library(${BINARY_NAME} STATIC ${SRC})
729	endif()
730
731	add_dependencies(${BINARY_NAME} version-info)
732	set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
733
734	target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
735	install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
736	if(UNIX AND NOT APPLE AND NOT HAIKU)
737		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
738		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
739		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
740		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
741		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
742		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
743		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
744		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
745		install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
746	endif()
747else()
748	set(BUILD_SHARED OFF)
749	set(BUILD_STATIC OFF)
750	find_library(${BINARY_NAME} ${BINARY_NAME})
751	if(NOT ${BINARY_NAME}_FOUND)
752		set(DISABLE_FRONTENDS ON)
753		set(BUILD_PERF OFF)
754		set(BUILD_TEST OFF)
755		set(BUILD_SUITE OFF)
756	endif()
757endif()
758
759if(BUILD_GL)
760	add_definitions(-DBUILD_GL)
761endif()
762
763if(BUILD_GLES2)
764	add_definitions(-DBUILD_GLES2)
765endif()
766
767if(DISABLE_FRONTENDS)
768	set(BUILD_SDL OFF)
769	set(BUILD_QT OFF)
770endif()
771
772if(BUILD_LIBRETRO)
773	file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
774	add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
775	set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
776	target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
777	install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
778endif()
779
780if(BUILD_OPENEMU)
781	find_library(FOUNDATION Foundation)
782	find_library(OPENEMUBASE OpenEmuBase)
783	file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
784	add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OE_SRC})
785	set_target_properties(${BINARY_NAME}-openemu PROPERTIES
786		MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
787		BUNDLE TRUE
788		BUNDLE_EXTENSION oecoreplugin
789		OUTPUT_NAME ${PROJECT_NAME}
790		COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
791	target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
792	install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
793endif()
794
795if(BUILD_SDL)
796	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
797	# The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
798	if(BUILD_SDL)
799		add_definitions(-DBUILD_SDL)
800	endif()
801endif()
802
803if(BUILD_QT)
804	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
805endif()
806
807if(BUILD_PERF)
808	set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c)
809	if(UNIX AND NOT APPLE)
810		list(APPEND PERF_LIB rt)
811	endif()
812
813	add_executable(${BINARY_NAME}-perf ${PERF_SRC})
814	target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
815	set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
816	install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
817	install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
818endif()
819
820if(BUILD_TEST)
821	add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
822	target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
823	set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
824	add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
825	target_link_libraries(tbl-fuzz ${BINARY_NAME})
826	set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
827	install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
828endif()
829
830if(NOT USE_CMOCKA)
831	set(BUILD_SUITE OFF)
832endif()
833if(BUILD_SUITE)
834	enable_testing()
835	include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
836	link_directories(${CMOCKA_LIBRARY_DIRS})
837
838	add_executable(${BINARY_NAME}-suite ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/suite-main.c ${TEST_SRC})
839	target_link_libraries(${BINARY_NAME}-suite ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
840	set_target_properties(${BINARY_NAME}-suite PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
841	add_test(${BINARY_NAME}-suite ${BINARY_NAME}-suite)
842endif()
843
844if(BUILD_PYTHON)
845	enable_testing()
846	add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
847endif()
848
849if(BUILD_EXAMPLE)
850	add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
851	target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
852	set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
853
854	if(BUILD_SDL)
855		add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
856		target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
857		set_target_properties(${BINARY_NAME}-example-client PROPERTIES
858		                      COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
859		                      INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
860	endif()
861endif()
862
863configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
864install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mgba COMPONENT lib${BINARY_NAME})
865
866# Packaging
867set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
868set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
869set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
870set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
871set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
872set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
873
874set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
875set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
876set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
877set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
878set(CPACK_DEBIAN_PACKAGE_SECTION "games")
879
880SET(CPACK_DEB_COMPONENT_INSTALL ON)
881
882set(CPACK_STRIP_FILES ${BINARY_NAME})
883
884install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
885
886include(CPack)
887
888# Summaries
889set(SUMMARY_GL_LIST)
890if(USE_EPOXY)
891	set(SUMMARY_GL_LIST "libepoxy")
892else()
893	if(BUILD_GL)
894		list(APPEND SUMMARY_GL_LIST "OpenGL")
895	endif()
896	if(BUILD_GLES2)
897		list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
898	endif()
899endif()
900if(NOT SUMMARY_GL_LIST)
901	set(SUMMARY_GL OFF)
902else()
903	string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
904endif()
905if(USE_LIBZIP)
906	set(SUMMARY_ZIP libzip)
907elseif(USE_MINIZIP)
908	set(SUMMARY_ZIP "minizip (external)")
909elseif(USE_ZLIB)
910	set(SUMMARY_ZIP "minizip (included)")
911else()
912	set(SUMMARY_ZIP OFF)
913endif()
914
915if(NOT QUIET)
916	message(STATUS "Build type: ${CMAKE_BUILD_TYPE}")
917	message(STATUS "Platforms:")
918	message(STATUS "	Game Boy Advance: ${M_CORE_GBA}")
919	message(STATUS "	Game Boy: ${M_CORE_GB}")
920	message(STATUS "Features:")
921	message(STATUS "	Debuggers: ${USE_DEBUGGERS}")
922	message(STATUS "	CLI debugger: ${USE_EDITLINE}")
923	message(STATUS "	GDB stub: ${USE_GDB_STUB}")
924	message(STATUS "	Video recording: ${USE_FFMPEG}")
925	message(STATUS "	GIF recording: ${USE_MAGICK}")
926	message(STATUS "	Screenshot/advanced savestate support: ${USE_PNG}")
927	message(STATUS "	ZIP support: ${SUMMARY_ZIP}")
928	message(STATUS "	7-Zip support: ${USE_LZMA}")
929	message(STATUS "	SQLite3 game database: ${USE_SQLITE3}")
930	message(STATUS "	OpenGL support: ${SUMMARY_GL}")
931	message(STATUS "Frontends:")
932	message(STATUS "	Qt: ${BUILD_QT}")
933	message(STATUS "	SDL (${SDL_VERSION}): ${BUILD_SDL}")
934	message(STATUS "	Profiling: ${BUILD_PERF}")
935	message(STATUS "	Test harness: ${BUILD_TEST}")
936	message(STATUS "	Test suite: ${BUILD_SUITE}")
937	message(STATUS "	Python bindings: ${BUILD_PYTHON}")
938	message(STATUS "	Examples: ${BUILD_EXAMPLE}")
939	message(STATUS "Cores:")
940	message(STATUS "	Libretro core: ${BUILD_LIBRETRO}")
941	if(APPLE)
942		message(STATUS "	OpenEmu core: ${BUILD_OPENEMU}")
943	endif()
944	message(STATUS "Libraries:")
945	message(STATUS "	Static: ${BUILD_STATIC}")
946	message(STATUS "	Shared: ${BUILD_SHARED}")
947endif()