CMakeLists.txt (view raw)
1cmake_minimum_required(VERSION 3.1)
2project(mGBA)
3set(BINARY_NAME mgba CACHE INTERNAL "Name of output binaries")
4if(NOT MSVC)
5 set(GCC_STD "c99")
6 if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_COMPILER_VERSION VERSION_LESS "4.3")
7 set(GCC_STD "gnu99")
8 endif()
9 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-missing-field-initializers -std=${GCC_STD}")
10else()
11 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -D_CRT_SECURE_NO_WARNINGS /wd4003 /wd4244 /wd4146")
12endif()
13set(USE_DEBUGGERS ON CACHE BOOL "Whether or not to enable the debugging infrastructure")
14if (NOT WIN32)
15 set(USE_EDITLINE ON CACHE BOOL "Whether or not to enable the CLI-mode debugger")
16endif()
17set(USE_GDB_STUB ON CACHE BOOL "Whether or not to enable the GDB stub ARM debugger")
18set(USE_FFMPEG ON CACHE BOOL "Whether or not to enable FFmpeg support")
19set(USE_ZLIB ON CACHE BOOL "Whether or not to enable zlib support")
20set(USE_MINIZIP ON CACHE BOOL "Whether or not to enable external minizip support")
21set(USE_PNG ON CACHE BOOL "Whether or not to enable PNG support")
22set(USE_LIBZIP ON CACHE BOOL "Whether or not to enable LIBZIP support")
23set(USE_MAGICK ON CACHE BOOL "Whether or not to enable ImageMagick support")
24set(USE_SQLITE3 ON CACHE BOOL "Whether or not to enable SQLite3 support")
25set(USE_ELF ON CACHE BOOL "Whether or not to enable ELF support")
26set(M_CORE_GBA ON CACHE BOOL "Build Game Boy Advance core")
27set(M_CORE_GB ON CACHE BOOL "Build Game Boy core")
28set(USE_LZMA ON CACHE BOOL "Whether or not to enable 7-Zip support")
29set(ENABLE_SCRIPTING ON CACHE BOOL "Whether or not to enable scripting support")
30set(BUILD_QT ON CACHE BOOL "Build Qt frontend")
31set(BUILD_SDL ON CACHE BOOL "Build SDL frontend")
32set(BUILD_LIBRETRO OFF CACHE BOOL "Build libretro core")
33if(APPLE)
34 set(BUILD_OPENEMU OFF CACHE BOOL "Build OpenEmu core")
35endif()
36set(BUILD_PERF OFF CACHE BOOL "Build performance profiling tool")
37set(BUILD_TEST OFF CACHE BOOL "Build testing harness")
38set(BUILD_SUITE OFF CACHE BOOL "Build test suite")
39set(BUILD_EXAMPLE OFF CACHE BOOL "Build example frontends")
40set(BUILD_PYTHON OFF CACHE BOOL "Build Python bindings")
41set(BUILD_STATIC OFF CACHE BOOL "Build a static library")
42set(BUILD_SHARED ON CACHE BOOL "Build a shared library")
43set(SKIP_LIBRARY OFF CACHE BOOL "Skip building the library (useful for only building libretro or OpenEmu cores)")
44set(BUILD_GL ON CACHE STRING "Build with OpenGL")
45set(BUILD_GLES2 OFF CACHE STRING "Build with OpenGL|ES 2")
46set(USE_EPOXY ON CACHE STRING "Build with libepoxy")
47set(DISABLE_DEPS OFF CACHE BOOL "Build without dependencies")
48if(WIN32)
49 set(WIN32_UNIX_PATHS OFF CACHE BOOL "Use Unix-like paths")
50 mark_as_advanced(WIN32_UNIX_PATHS)
51endif()
52file(GLOB ARM_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/*.c)
53file(GLOB ARM_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/test/*.c)
54file(GLOB LR35902_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/*.c)
55file(GLOB LR35902_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/test/*.c)
56file(GLOB GBA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/*.c)
57file(GLOB GBA_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/test/*.c)
58file(GLOB GB_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/*.c)
59file(GLOB GB_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/test/*.c)
60file(GLOB GBA_CHEATS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/cheats/*.c)
61file(GLOB GBA_RR_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/rr/*.c)
62file(GLOB CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/*.c)
63file(GLOB CORE_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/core/test/*.c)
64file(GLOB UTIL_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/*.[cSs])
65file(GLOB UTIL_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/test/*.c)
66file(GLOB GUI_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/gui/*.c ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/gui/*.c)
67file(GLOB GBA_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/renderers/*.c)
68file(GLOB GBA_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/sio/*.c)
69file(GLOB GBA_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/extra/*.c)
70file(GLOB GB_SIO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/sio/*.c)
71file(GLOB GB_RENDERER_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/renderers/*.c)
72file(GLOB GB_EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/extra/*.c)
73file(GLOB THIRD_PARTY_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/inih/*.c)
74file(GLOB EXTRA_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/feature/*.c)
75set(CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-mem.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fifo.c)
76set(VFS_SRC)
77source_group("ARM core" FILES ${ARM_SRC})
78source_group("LR35902 core" FILES ${LR35902_SRC})
79source_group("GBA board" FILES ${GBA_SRC} ${GBA_RENDERER_SRC} ${GBA_SIO_SRC})
80source_group("GBA extra" FILES ${GBA_CHEATS_SRC} ${GBA_RR_SRC})
81source_group("GB board" FILES ${GB_SRC} ${GB_SIO_SRC})
82source_group("Utilities" FILES ${UTIL_SRC})
83include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/include ${CMAKE_CURRENT_SOURCE_DIR}/src)
84
85if(NOT CMAKE_BUILD_TYPE)
86 set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type (e.g. Release or Debug)" FORCE)
87endif()
88
89if(NOT WIN32 OR WIN32_UNIX_PATHS)
90 include(GNUInstallDirs)
91else()
92 set(CMAKE_INSTALL_LIBDIR ".")
93 set(CMAKE_INSTALL_BINDIR ".")
94 set(CMAKE_INSTALL_DATADIR ".")
95 set(CMAKE_INSTALL_DOCDIR ".")
96 set(CMAKE_INSTALL_INCLUDEDIR "include")
97endif()
98
99set(LIBDIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installed library directory")
100mark_as_advanced(LIBDIR)
101
102if (BUILD_LIBRETRO)
103 set(LIBRETRO_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (Libretro)")
104 mark_as_advanced(LIBRETRO_LIBDIR)
105endif()
106
107if (BUILD_OPENEMU)
108 set(OE_LIBDIR "${LIBDIR}" CACHE PATH "Installed library directory (OpenEmu)")
109 mark_as_advanced(OE_LIBDIR)
110endif()
111
112
113set(CMAKE_INSTALL_RPATH "${LIBDIR}")
114
115if (NOT DEFINED MANDIR)
116 set(MANDIR ${CMAKE_INSTALL_MANDIR})
117endif()
118
119# Function definitions
120include(FindPkgConfig)
121function(find_feature FEATURE_NAME FEATURE_REQUIRES)
122 if (NOT ${FEATURE_NAME})
123 return()
124 endif()
125 if (DISABLE_DEPS)
126 set(${FEATURE_NAME} OFF PARENT_SCOPE)
127 return()
128 endif()
129 foreach(REQUIRE ${FEATURE_REQUIRES})
130 if(NOT ${REQUIRE}_FOUND)
131 find_package(${REQUIRE} QUIET)
132 if(NOT ${REQUIRE}_FOUND)
133 pkg_search_module(${REQUIRE} ${REQUIRE})
134 if (NOT ${REQUIRE}_FOUND)
135 message(WARNING "Requested module ${REQUIRE} missing for feature ${FEATURE_NAME}. Feature disabled.")
136 set(${FEATURE_NAME} OFF PARENT_SCOPE)
137 return()
138 endif()
139 endif()
140 endif()
141 string(TOUPPER ${REQUIRE} UREQUIRE)
142 set(${UREQUIRE}_CFLAGS_OTHER ${${REQUIRE}_CFLAGS_OTHER} PARENT_SCOPE)
143 set(${UREQUIRE}_FOUND ${${REQUIRE}_FOUND} PARENT_SCOPE)
144 set(${UREQUIRE}_INCLUDE_DIRS ${${REQUIRE}_INCLUDE_DIRS} PARENT_SCOPE)
145 set(${UREQUIRE}_VERSION_STRING ${${REQUIRE}_VERSION_STRING} PARENT_SCOPE)
146 if (APPLE)
147 set(IS_FRAMEWORK OFF)
148 set(LIBS)
149 foreach(LIB IN LISTS ${REQUIRE}_LIBRARIES)
150 if(LIB STREQUAL "-framework")
151 set(IS_FRAMEWORK ON)
152 elseif(IS_FRAMEWORK)
153 list(APPEND LIBS "-framework ${LIB}")
154 set(IS_FRAMEWORK OFF)
155 else()
156 list(APPEND LIBS ${LIB})
157 endif()
158 endforeach()
159 set(${UREQUIRE}_LIBRARIES ${LIBS} PARENT_SCOPE)
160 else()
161 set(${UREQUIRE}_LIBRARIES ${${REQUIRE}_LIBRARIES} PARENT_SCOPE)
162 endif()
163 set(${UREQUIRE}_LIBRARY_DIRS ${${REQUIRE}_LIBRARY_DIRS} PARENT_SCOPE)
164 set(${UREQUIRE}_LDFLAGS_OTHER ${${REQUIRE}_LDFLAGS_OTHER} PARENT_SCOPE)
165 endforeach()
166endfunction()
167
168# Version information
169add_custom_target(version-info ALL
170 COMMAND ${CMAKE_COMMAND}
171 -DBINARY_NAME=${BINARY_NAME}
172 -DCONFIG_FILE=${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in
173 -DOUT_FILE=${CMAKE_CURRENT_BINARY_DIR}/version.c
174 -P ${CMAKE_CURRENT_SOURCE_DIR}/version.cmake
175 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
176
177include(${CMAKE_CURRENT_SOURCE_DIR}/version.cmake)
178configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/version.c.in ${CMAKE_CURRENT_BINARY_DIR}/version.c)
179
180list(APPEND UTIL_SRC ${CMAKE_CURRENT_BINARY_DIR}/version.c)
181source_group("Generated sources" FILES ${CMAKE_CURRENT_BINARY_DIR}/version.c)
182
183# Advanced settings
184if(NOT DEFINED 3DS AND NOT (CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_COMPILER_VERSION VERSION_LESS "4.5"))
185 # LTO appears to make 3DS binary slower
186 set(DEFAULT_LTO ON)
187else()
188 set(DEFAULT_LTO OFF)
189endif()
190
191set(BUILD_LTO ${DEFAULT_LTO} CACHE BOOL "Build with link-time optimization")
192set(BUILD_PGO OFF CACHE BOOL "Build with profiling-guided optimization")
193set(PGO_STAGE_2 CACHE BOOL "Rebuild for profiling-guided optimization after profiles have been generated")
194set(PGO_DIR "/tmp/gba-pgo/" CACHE PATH "Profiling-guided optimization profiles path")
195mark_as_advanced(BUILD_LTO BUILD_PGO PGO_STAGE_2 PGO_DIR)
196set(PGO_PRE_FLAGS "-fprofile-generate=${PGO_DIR} -fprofile-arcs")
197set(PGO_POST_FLAGS "-fprofile-use=${PGO_DIR} -fbranch-probabilities")
198
199if(BUILD_PGO AND NOT PGO_STAGE_2)
200 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_PRE_FLAGS}")
201 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
202 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_PRE_FLAGS}")
203elseif(BUILD_PGO AND PGO_STAGE_2)
204 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${PGO_POST_FLAGS}")
205 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${PGO_POST_FLAGS}")
206 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${PGO_POST_FLAGS}")
207endif()
208
209# Platform support
210if(WIN32)
211 set(WIN32_VERSION "${LIB_VERSION_MAJOR},${LIB_VERSION_MINOR},${LIB_VERSION_PATCH}")
212 add_definitions(-D_WIN32_WINNT=0x0600)
213 list(APPEND OS_LIB ws2_32 shlwapi)
214 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/vfs-w32.c)
215 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/windows/*.c)
216 source_group("Windows-specific code" FILES ${OS_SRC})
217 if(MSVC)
218 add_definitions(-DNOMINMAX -DWIN32_LEAN_AND_MEAN)
219 set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
220 endif()
221elseif(UNIX)
222 set(USE_PTHREADS ON)
223 add_definitions(-DUSE_PTHREADS)
224
225 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
226 add_definitions(-D_GNU_SOURCE)
227 endif()
228 if(NOT APPLE AND NOT HAIKU)
229 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
230 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
231 endif()
232
233 list(APPEND CORE_VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-fd.c ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-dirent.c)
234 file(GLOB OS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/posix/*.c)
235 source_group("POSIX-specific code" FILES ${OS_SRC})
236endif()
237
238if(APPLE)
239 add_definitions(-D_DARWIN_C_SOURCE)
240 if(CMAKE_SYSTEM_VERSION VERSION_GREATER "10.5.8")
241 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mmacosx-version-min=10.6")
242 endif()
243endif()
244
245if(NOT HAIKU AND NOT MSVC AND NOT PSP2)
246 set(M_LIBRARY m)
247endif()
248list(APPEND OS_LIB ${M_LIBRARY})
249
250if(APPLE OR CMAKE_C_COMPILER_ID STREQUAL "GNU" AND BUILD_LTO)
251 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -flto")
252 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -flto")
253endif()
254
255if(BUILD_BBB OR BUILD_RASPI OR BUILD_PANDORA)
256 if(NOT BUILD_EGL)
257 add_definitions(-DCOLOR_16_BIT -DCOLOR_5_6_5)
258 endif()
259endif()
260
261if(BUILD_RASPI)
262 set(BUILD_GL OFF CACHE BOOL "OpenGL not supported" FORCE)
263endif()
264
265if(BUILD_PANDORA)
266 add_definitions(-DBUILD_PANDORA)
267endif()
268
269if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
270 enable_language(ASM)
271endif()
272
273if(PSP2 OR WII)
274 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-format")
275endif()
276
277if(DEFINED 3DS OR DEFINED PSP2 OR DEFINED WII)
278 set(USE_DEBUGGERS OFF)
279 set(USE_SQLITE3 OFF)
280endif()
281
282if(DEFINED 3DS)
283 add_definitions(-DFIXED_ROM_BUFFER)
284endif()
285
286if(NOT M_CORE_GBA)
287 set(USE_GDB_STUB OFF)
288endif()
289
290if(NOT USE_DEBUGGERS)
291 set(USE_EDITLINE OFF)
292 set(USE_GDB_STUB OFF)
293endif()
294
295if(WII)
296 add_definitions(-U__STRICT_ANSI__)
297endif()
298
299if(DEFINED 3DS)
300 add_definitions(-D_GNU_SOURCE)
301endif()
302
303include(CheckFunctionExists)
304check_function_exists(strdup HAVE_STRDUP)
305check_function_exists(strndup HAVE_STRNDUP)
306if(NOT DEFINED PSP2)
307 check_function_exists(localtime_r HAVE_LOCALTIME_R)
308endif()
309if(NOT CMAKE_SYSTEM_NAME STREQUAL "Generic")
310 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
311 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
312 # The strtof_l on Linux not actually exposed nor actually strtof_l
313 set(HAVE_STRTOF_L OFF)
314 else()
315 check_function_exists(strtof_l HAVE_STRTOF_L)
316 endif()
317 check_function_exists(newlocale HAVE_NEWLOCALE)
318 check_function_exists(freelocale HAVE_FREELOCALE)
319 check_function_exists(uselocale HAVE_USELOCALE)
320 check_function_exists(setlocale HAVE_SETLOCALE)
321else()
322 if(DEFINED 3DS OR DEFINED WII)
323 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,snprintf_l)
324 check_function_exists(snprintf_l HAVE_SNPRINTF_L)
325 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,strtof_l)
326 check_function_exists(strtof_l HAVE_STRTOF_L)
327 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,newlocale)
328 check_function_exists(newlocale HAVE_NEWLOCALE)
329 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,freelocale)
330 check_function_exists(freelocale HAVE_FREELOCALE)
331 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,uselocale)
332 check_function_exists(uselocale HAVE_USELOCALE)
333 set(CMAKE_REQUIRED_FLAGS -Wl,--require-defined,setlocale)
334 check_function_exists(setlocale HAVE_SETLOCALE)
335 unset(CMAKE_REQUIRED_FLAGS)
336 endif()
337 if(NOT DEFINED 3DS AND NOT DEFINED PSP2 AND NOT DEFINED WII)
338 set(DISABLE_DEPS ON CACHE BOOL "This platform cannot build with dependencies" FORCE)
339 endif()
340 set(DISABLE_FRONTENDS ON)
341 set(MINIMAL_CORE ON)
342 set(ENABLE_EXTRA ON)
343endif()
344
345check_function_exists(chmod HAVE_CHMOD)
346check_function_exists(umask HAVE_UMASK)
347
348set(FUNCTION_DEFINES)
349
350if(HAVE_STRDUP)
351 list(APPEND FUNCTION_DEFINES HAVE_STRDUP)
352endif()
353
354if(HAVE_STRNDUP)
355 list(APPEND FUNCTION_DEFINES HAVE_STRNDUP)
356endif()
357
358if(HAVE_LOCALTIME_R)
359 list(APPEND FUNCTION_DEFINES HAVE_LOCALTIME_R)
360endif()
361
362if(HAVE_NEWLOCALE AND HAVE_FREELOCALE AND HAVE_USELOCALE OR APPLE)
363 list(APPEND FUNCTION_DEFINES HAVE_LOCALE)
364 if (HAVE_STRTOF_L)
365 list(APPEND FUNCTION_DEFINES HAVE_STRTOF_L)
366 endif()
367 if (HAVE_SNPRINTF_L)
368 list(APPEND FUNCTION_DEFINES HAVE_SNPRINTF_L)
369 endif()
370endif()
371
372if(HAVE_SETLOCALE)
373 list(APPEND FUNCTION_DEFINES HAVE_SETLOCALE)
374endif()
375
376if(HAVE_CHMOD)
377 list(APPEND FUNCTION_DEFINES HAVE_CHMOD)
378endif()
379
380if(HAVE_UMASK)
381 list(APPEND FUNCTION_DEFINES HAVE_UMASK)
382endif()
383
384# Feature dependencies
385set(FEATURE_DEFINES)
386set(FEATURE_FLAGS)
387set(FEATURES)
388set(ENABLES)
389if(CMAKE_SYSTEM_NAME MATCHES .*BSD)
390 set(LIBEDIT_LIBRARIES -ledit)
391 if (CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
392 list(APPEND LIBEDIT_LIBRARIES -ltermcap)
393 endif()
394else()
395 find_feature(USE_EDITLINE "libedit")
396endif()
397if(BUILD_GL)
398 find_package(OpenGL QUIET)
399 if(NOT OPENGL_FOUND)
400 set(BUILD_GL OFF CACHE BOOL "OpenGL not found" FORCE)
401 endif()
402endif()
403if(NOT BUILD_GL)
404 set(OPENGLE_LIBRARY "" CACHE PATH "" FORCE)
405endif()
406if(BUILD_GLES2 AND NOT BUILD_RASPI)
407 find_path(OPENGLES2_INCLUDE_DIR NAMES GLES2/gl2.h)
408 find_library(OPENGLES2_LIBRARY NAMES GLESv2 GLESv2_CM)
409 if(NOT OPENGLES2_INCLUDE_DIR OR NOT OPENGLES2_LIBRARY)
410 set(BUILD_GLES2 OFF CACHE BOOL "OpenGL|ES 2 not found" FORCE)
411 endif()
412endif()
413if(NOT BUILD_GLES2)
414 set(OPENGLES2_LIBRARY "" CACHE PATH "" FORCE)
415endif()
416set(WANT_ZLIB ${USE_ZLIB})
417set(WANT_PNG ${USE_PNG})
418set(WANT_LIBZIP ${USE_LIBZIP})
419set(WANT_SQLITE3 ${USE_SQLITE3})
420set(USE_CMOCKA ${BUILD_SUITE})
421
422find_feature(USE_FFMPEG "libavcodec;libavformat;libavresample;libavutil;libswscale")
423find_feature(USE_ZLIB "ZLIB")
424find_feature(USE_MINIZIP "minizip")
425find_feature(USE_PNG "PNG")
426find_feature(USE_LIBZIP "libzip")
427find_feature(USE_MAGICK "MagickWand")
428find_feature(USE_EPOXY "epoxy")
429find_feature(USE_CMOCKA "cmocka")
430find_feature(USE_SQLITE3 "sqlite3")
431find_feature(USE_ELF "libelf")
432find_feature(ENABLE_PYTHON "PythonLibs")
433
434# Features
435set(DEBUGGER_SRC
436 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/debugger.c
437 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/parser.c
438 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/symbols.c
439 ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/cli-debugger.c)
440
441file(GLOB DEBUGGER_TEST_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/test/*.c)
442
443set(FEATURE_SRC)
444set(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6")
445
446if(DISABLE_DEPS)
447 set(USE_GDB_STUB OFF)
448endif()
449
450if(USE_EDITLINE)
451 list(APPEND FEATURES EDITLINE)
452 include_directories(AFTER ${LIBEDIT_INCLUDE_DIRS})
453 link_directories(${LIBEDIT_LIBRARY_DIRS})
454 set(DEBUGGER_LIB ${LIBEDIT_LIBRARIES})
455 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libedit2")
456 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/editline/cli-el-backend.c")
457else()
458 set(DEBUGGER_LIB "")
459endif()
460
461if(USE_GDB_STUB)
462 list(APPEND FEATURES GDB_STUB)
463 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/debugger/gdb-stub.c)
464endif()
465source_group("Debugger" FILES ${DEBUGGER_SRC})
466
467if(USE_FFMPEG)
468 list(APPEND FEATURES FFMPEG)
469 pkg_search_module(LIBSWRESAMPLE QUIET libswresample)
470 if(NOT LIBSWRESAMPLE_FOUND)
471 list(APPEND FEATURES LIBAV)
472 endif()
473 include_directories(AFTER ${LIBAVCODEC_INCLUDE_DIRS} ${LIBAVFORMAT_INCLUDE_DIRS} ${LIBAVRESAMPLE_INCLUDE_DIRS} ${LIBAVUTIL_INCLUDE_DIRS} ${LIBSWSCALE_INCLUDE_DIRS})
474 link_directories(${LIBAVCODEC_LIBRARY_DIRS} ${LIBAVFORMAT_LIBRARY_DIRS} ${LIBAVRESAMPLE_LIBRARY_DIRS} ${LIBAVUTIL_LIBRARY_DIRS} ${LIBSWSCALE_LIBRARY_DIRS})
475 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/ffmpeg/ffmpeg-encoder.c")
476 string(REGEX MATCH "^[0-9]+" LIBAVCODEC_VERSION_MAJOR ${libavcodec_VERSION})
477 string(REGEX MATCH "^[0-9]+" LIBAVFORMAT_VERSION_MAJOR ${libavformat_VERSION})
478 string(REGEX MATCH "^[0-9]+" LIBAVRESAMPLE_VERSION_MAJOR ${libavresample_VERSION})
479 string(REGEX MATCH "^[0-9]+" LIBAVUTIL_VERSION_MAJOR ${libavutil_VERSION})
480 string(REGEX MATCH "^[0-9]+" LIBSWSCALE_VERSION_MAJOR ${libswscale_VERSION})
481 list(APPEND DEPENDENCY_LIB ${LIBAVCODEC_LIBRARIES} ${LIBAVFORMAT_LIBRARIES} ${LIBAVRESAMPLE_LIBRARIES} ${LIBAVUTIL_LIBRARIES} ${LIBSWSCALE_LIBRARIES})
482 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavcodec${LIBAVCODEC_VERSION_MAJOR}|libavcodec-extra-${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg${LIBAVCODEC_VERSION_MAJOR}|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
483 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavformat${LIBAVFORMAT_VERSION_MAJOR}|libavformat-ffmpeg${LIBAVFORMAT_VERSION_MAJOR}")
484 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavresample${LIBAVRESAMPLE_VERSION_MAJOR}|libavresample-ffmpeg${LIBAVRESAMPLE_VERSION_MAJOR}")
485 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libavutil${LIBAVUTIL_VERSION_MAJOR}|libavutil-ffmpeg${LIBAVUTIL_VERSION_MAJOR}")
486 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libswscale${LIBSWSCALE_VERSION_MAJOR}|libswscale-ffmpeg${LIBSWSCALE_VERSION_MAJOR}")
487 set(CPACK_DEBIAN_PACKAGE_RECOMMENDS "libavcodec-extra|libavcodec-ffmpeg-extra${LIBAVCODEC_VERSION_MAJOR}")
488 if(APPLE)
489 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
490 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -framework VideoDecodeAcceleration -framework CoreVideo")
491 endif()
492endif()
493
494list(APPEND THIRD_PARTY_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/blip_buf/blip_buf.c")
495
496if(USE_MAGICK)
497 list(APPEND FEATURES MAGICK)
498 include_directories(AFTER ${MAGICKWAND_INCLUDE_DIRS})
499 link_directories(${MAGICKWAND_LIBRARY_DIRS})
500 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/imagemagick/imagemagick-gif-encoder.c")
501 list(APPEND DEPENDENCY_LIB ${MAGICKWAND_LIBRARIES})
502 string(REGEX MATCH "^[0-9]+\\.[0-9]+" MAGICKWAND_VERSION_PARTIAL ${MagickWand_VERSION})
503 string(REGEX MATCH "^[0-9]+" MAGICKWAND_VERSION_MAJOR ${MagickWand_VERSION})
504 if(${MAGICKWAND_VERSION_PARTIAL} EQUAL "6.7")
505 set(MAGICKWAND_DEB_VERSION "5")
506 elseif(${MagickWand_VERSION} EQUAL "6.9.7")
507 set(MAGICKWAND_DEB_VERSION "-6.q16-3")
508 else()
509 set(MAGICKWAND_DEB_VERSION "-6.q16-2")
510 endif()
511 list(APPEND FEATURE_DEFINES MAGICKWAND_VERSION_MAJOR=${MAGICKWAND_VERSION_MAJOR})
512 list(APPEND FEATURE_FLAGS ${MAGICKWAND_CFLAGS_OTHER})
513
514 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libmagickwand${MAGICKWAND_DEB_VERSION}")
515endif()
516
517if(WANT_ZLIB AND NOT USE_ZLIB)
518 set(SKIP_INSTALL_ALL ON)
519 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib zlib)
520 set_property(TARGET zlibstatic PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/zlib;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib)
521 set_property(TARGET zlib PROPERTY EXCLUDE_FROM_ALL ON)
522 set_property(TARGET example PROPERTY EXCLUDE_FROM_ALL ON)
523 set_property(TARGET minigzip PROPERTY EXCLUDE_FROM_ALL ON)
524 set(ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
525 set(ZLIB_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib ${CMAKE_CURRENT_BINARY_DIR}/zlib)
526 set(ZLIB_LIBRARY zlibstatic)
527 list(APPEND DEPENDENCY_LIB zlibstatic)
528 set(USE_ZLIB ON)
529endif()
530
531if(USE_ZLIB)
532 list(APPEND FEATURES ZLIB)
533 include_directories(AFTER ${ZLIB_INCLUDE_DIRS})
534 list(APPEND DEPENDENCY_LIB ${ZLIB_LIBRARIES})
535 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},zlib1g")
536 set(HAVE_CRC32 ON)
537 list(APPEND OS_LIB ${ZLIB_LIBRARIES})
538else()
539 # zlib pulls in crc32
540 check_function_exists(crc32 HAVE_CRC32)
541endif()
542
543if(HAVE_CRC32)
544 list(APPEND FUNCTION_DEFINES HAVE_CRC32)
545endif()
546
547if(WANT_PNG AND USE_ZLIB AND NOT USE_PNG)
548 set(PNG_STATIC ON CACHE BOOL "" FORCE)
549 set(PNG_SHARED OFF CACHE BOOL "" FORCE)
550 set(PNG_TESTS OFF CACHE BOOL "" FORCE)
551 set(SKIP_INSTALL_ALL ON)
552 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng libpng)
553 set_property(TARGET png16_static PROPERTY INCLUDE_DIRECTORIES ${CMAKE_CURRENT_BINARY_DIR}/libpng;${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng;${ZLIB_INCLUDE_DIRS})
554 set(PNG_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/libpng ${CMAKE_CURRENT_BINARY_DIR}/libpng)
555 list(APPEND DEPENDENCY_LIB png16_static)
556 set(USE_PNG ON)
557endif()
558
559if(USE_PNG)
560 list(APPEND FEATURES PNG)
561 include_directories(AFTER ${PNG_INCLUDE_DIRS})
562 list(APPEND DEPENDENCY_LIB ${PNG_LIBRARIES} ${ZLIB_LIBRARIES})
563 if(PNG_VERSION_STRING)
564 string(REGEX MATCH "^[0-9]+\\.[0-9]+" PNG_VERSION_PARTIAL ${PNG_VERSION_STRING})
565 if(${PNG_VERSION_PARTIAL} STREQUAL "1.6")
566 set(PNG_DEB_VERSION "16-16")
567 else()
568 set(PNG_DEB_VERSION "12-0")
569 endif()
570 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libpng${PNG_DEB_VERSION}")
571 endif()
572endif()
573
574if(WANT_SQLITE3 AND NOT USE_SQLITE3)
575 list(APPEND FEATURE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/sqlite3.c)
576 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/sqlite3/)
577 set(USE_SQLITE3 ON)
578endif()
579
580if(USE_LIBZIP)
581 include_directories(AFTER ${LIBZIP_INCLUDE_DIRS})
582 link_directories(${LIBZIP_LIBRARY_DIRS})
583 list(APPEND DEPENDENCY_LIB ${LIBZIP_LIBRARIES})
584 list(APPEND FEATURES LIBZIP)
585 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
586 string(REGEX MATCH "^[0-9]+" LIBZIP_VERSION_MAJOR ${libzip_VERSION})
587 if (LIBZIP_VERSION_MAJOR LESS 1)
588 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip2")
589 elseif(LIBZIP_VERSION_MAJOR EQUAL 1)
590 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libzip4")
591 else()
592 message(AUTHOR_WARNING Unknown version of libzip detected: ${libzip_VERSION})
593 endif()
594elseif(USE_MINIZIP)
595 include_directories(AFTER ${MINIZIP_INCLUDE_DIRS})
596 link_directories(${MINIZIP_LIBRARY_DIRS})
597 list(APPEND DEPENDENCY_LIB ${MINIZIP_LIBRARIES})
598 list(APPEND FEATURES MINIZIP)
599 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c)
600 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libminizip1")
601elseif(USE_ZLIB)
602 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-zip.c
603 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
604 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c)
605 if(NOT MSVC)
606 set_source_files_properties(
607 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/ioapi.c
608 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/zlib/contrib/minizip/unzip.c
609 PROPERTIES COMPILE_FLAGS "-Wno-unused-parameter -Wno-implicit-function-declaration")
610 endif()
611endif()
612
613if (USE_LZMA)
614 include_directories(AFTER ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma)
615 add_definitions(-D_7ZIP_PPMD_SUPPPORT)
616 list(APPEND VFS_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/util/vfs/vfs-lzma.c)
617 set(LZMA_SRC
618 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zAlloc.c
619 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zArcIn.c
620 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf.c
621 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zBuf2.c
622 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrc.c
623 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zCrcOpt.c
624 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zDec.c
625 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/CpuArch.c
626 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Delta.c
627 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/LzmaDec.c
628 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Lzma2Dec.c
629 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra.c
630 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bra86.c
631 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/BraIA64.c
632 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Bcj2.c
633 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7.c
634 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/Ppmd7Dec.c
635 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zFile.c
636 ${CMAKE_CURRENT_SOURCE_DIR}/src/third-party/lzma/7zStream.c)
637 list(APPEND VFS_SRC ${LZMA_SRC})
638 list(APPEND FEATURES LZMA)
639endif()
640
641if(USE_EPOXY)
642 add_definitions(-DBUILD_GL -DBUILD_GLES2)
643 list(APPEND FEATURES EPOXY)
644 include_directories(AFTER ${EPOXY_INCLUDE_DIRS})
645 set(OPENGLES2_LIBRARY ${EPOXY_LIBRARIES})
646 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libepoxy0")
647endif()
648
649if(USE_SQLITE3)
650 list(APPEND FEATURES SQLITE3)
651 include_directories(AFTER ${SQLITE3_INCLUDE_DIRS})
652 list(APPEND DEPENDENCY_LIB ${SQLITE3_LIBRARIES})
653 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libsqlite3-0")
654 list(APPEND FEATURE_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/feature/sqlite3/no-intro.c")
655endif()
656
657if(USE_ELF)
658 list(APPEND FEATURES ELF)
659 include_directories(AFTER ${LIBELF_INCLUDE_DIRS})
660 list(APPEND DEPENDENCY_LIB ${LIBELF_LIBRARIES})
661 set(CPACK_DEBIAN_PACKAGE_DEPENDS "${CPACK_DEBIAN_PACKAGE_DEPENDS},libelfg0")
662endif()
663
664if(ENABLE_SCRIPTING)
665 list(APPEND ENABLES SCRIPTING)
666
667 if(BUILD_PYTHON)
668 find_package(PythonLibs ${USE_PYTHON_VERSION})
669 list(APPEND DEPENDENCY_LIB ${PYTHON_LIBRARIES})
670 include_directories(AFTER ${PYTHON_INCLUDE_DIRS})
671 list(APPEND ENABLES PYTHON)
672 endif()
673endif()
674
675set(TEST_SRC ${CORE_TEST_SRC})
676if(M_CORE_GB)
677 add_definitions(-DM_CORE_GB)
678 list(APPEND CORE_SRC
679 ${LR35902_SRC}
680 ${GB_SRC}
681 ${GB_RENDERER_SRC})
682 list(APPEND DEBUGGER_SRC
683 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/cli-debugger.c
684 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/debugger.c
685 ${CMAKE_CURRENT_SOURCE_DIR}/src/lr35902/debugger/memory-debugger.c
686 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/cli.c
687 ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/debugger/symbols.c)
688 list(APPEND TEST_SRC
689 ${LR35902_TEST_SRC}
690 ${GB_TEST_SRC})
691endif()
692
693if(M_CORE_GBA)
694 add_definitions(-DM_CORE_GBA)
695 list(APPEND CORE_SRC
696 ${ARM_SRC}
697 ${GBA_SRC}
698 ${GBA_CHEATS_SRC}
699 ${GBA_RENDERER_SRC})
700 list(APPEND DEBUGGER_SRC
701 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/cli-debugger.c
702 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/debugger.c
703 ${CMAKE_CURRENT_SOURCE_DIR}/src/arm/debugger/memory-debugger.c
704 ${CMAKE_CURRENT_SOURCE_DIR}/src/gba/debugger/cli.c)
705 list(APPEND TEST_SRC
706 ${ARM_TEST_SRC}
707 ${GBA_TEST_SRC})
708 if(NOT M_CORE_GB)
709 list(APPEND CORE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/gb/audio.c)
710 endif()
711endif()
712
713if(USE_DEBUGGERS)
714 list(APPEND FEATURE_SRC ${DEBUGGER_SRC})
715 list(APPEND TEST_SRC ${DEBUGGER_TEST_SRC})
716 list(APPEND FEATURES DEBUGGERS)
717endif()
718
719foreach(FEATURE IN LISTS FEATURES)
720 list(APPEND FEATURE_DEFINES "USE_${FEATURE}")
721endforeach()
722
723foreach(ENABLE IN LISTS ENABLES)
724 list(APPEND FEATURE_DEFINES "ENABLE_${ENABLE}")
725endforeach()
726
727source_group("Virtual files" FILES ${CORE_VFS_SRC} ${VFS_SRC})
728source_group("Extra features" FILES ${FEATURE_SRC})
729source_group("Third-party code" FILES ${THIRD_PARTY_SRC})
730
731# Platform binaries
732if(DEFINED 3DS)
733 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/3ds ${CMAKE_CURRENT_BINARY_DIR}/3ds)
734endif()
735
736if(DEFINED WII)
737 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/wii ${CMAKE_CURRENT_BINARY_DIR}/wii)
738endif()
739
740if(DEFINED PSP2)
741 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/psp2 ${CMAKE_CURRENT_BINARY_DIR}/psp2)
742endif()
743
744# Binaries
745list(APPEND CORE_SRC
746 ${UTIL_SRC}
747 ${CORE_VFS_SRC}
748 ${OS_SRC}
749 ${THIRD_PARTY_SRC})
750list(APPEND TEST_SRC ${UTIL_TEST_SRC})
751
752set(SRC ${CORE_SRC} ${VFS_SRC})
753if(NOT MINIMAL_CORE)
754 set(ENABLE_EXTRA ON)
755 if(M_CORE_GBA)
756 list(APPEND SRC
757 ${GBA_SIO_SRC})
758 endif()
759 if(M_CORE_GB)
760 list(APPEND SRC
761 ${GB_SIO_SRC})
762 endif()
763 list(APPEND SRC
764 ${FEATURE_SRC})
765endif()
766
767if(ENABLE_EXTRA)
768 if(M_CORE_GBA)
769 list(APPEND SRC
770 ${GBA_RR_SRC}
771 ${GBA_EXTRA_SRC})
772 endif()
773 if(M_CORE_GB)
774 list(APPEND SRC
775 ${GB_EXTRA_SRC})
776 endif()
777 list(APPEND SRC
778 ${EXTRA_SRC})
779endif()
780
781if(NOT SKIP_LIBRARY)
782 if(NOT BUILD_STATIC AND NOT BUILD_SHARED)
783 set(BUILD_SHARED ON)
784 endif()
785
786 if(BUILD_SHARED)
787 add_library(${BINARY_NAME} SHARED ${SRC} ${VFS_SRC})
788 if(BUILD_STATIC)
789 add_library(${BINARY_NAME}-static STATIC ${SRC})
790 set_target_properties(${BINARY_NAME}-static PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}" COMPILE_OPTIONS "${FEATURE_FLAGS}")
791 install(TARGETS ${BINARY_NAME}-static DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
792 add_dependencies(${BINARY_NAME}-static version-info)
793 endif()
794 else()
795 add_library(${BINARY_NAME} STATIC ${SRC})
796 endif()
797
798 add_dependencies(${BINARY_NAME} version-info)
799 set_target_properties(${BINARY_NAME} PROPERTIES VERSION ${LIB_VERSION_STRING} SOVERSION ${LIB_VERSION_ABI} COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}" COMPILE_OPTIONS "${FEATURE_FLAGS}")
800
801 target_link_libraries(${BINARY_NAME} ${DEBUGGER_LIB} ${DEPENDENCY_LIB} ${OS_LIB})
802 install(TARGETS ${BINARY_NAME} LIBRARY DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME} NAMELINK_SKIP ARCHIVE DESTINATION ${LIBDIR} RUNTIME DESTINATION ${LIBDIR} COMPONENT lib${BINARY_NAME})
803 if(UNIX AND NOT APPLE AND NOT HAIKU)
804 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-16.png DESTINATION share/icons/hicolor/16x16/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
805 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-24.png DESTINATION share/icons/hicolor/24x24/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
806 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-32.png DESTINATION share/icons/hicolor/32x32/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
807 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-48.png DESTINATION share/icons/hicolor/48x48/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
808 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-64.png DESTINATION share/icons/hicolor/64x64/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
809 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-96.png DESTINATION share/icons/hicolor/96x96/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
810 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-128.png DESTINATION share/icons/hicolor/128x128/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
811 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-256.png DESTINATION share/icons/hicolor/256x256/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
812 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/res/mgba-512.png DESTINATION share/icons/hicolor/512x512/apps RENAME mgba.png COMPONENT lib${BINARY_NAME})
813 endif()
814else()
815 set(BUILD_SHARED OFF)
816 set(BUILD_STATIC OFF)
817 find_library(${BINARY_NAME} ${BINARY_NAME})
818 if(NOT ${BINARY_NAME}_FOUND)
819 set(DISABLE_FRONTENDS ON)
820 set(BUILD_PERF OFF)
821 set(BUILD_TEST OFF)
822 set(BUILD_SUITE OFF)
823 endif()
824endif()
825
826if(BUILD_GL)
827 add_definitions(-DBUILD_GL)
828endif()
829
830if(BUILD_GLES2)
831 add_definitions(-DBUILD_GLES2)
832endif()
833
834if(DISABLE_FRONTENDS)
835 set(BUILD_SDL OFF)
836 set(BUILD_QT OFF)
837endif()
838
839if(BUILD_PYTHON)
840 enable_testing()
841 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/python ${CMAKE_CURRENT_BINARY_DIR}/python)
842endif()
843
844if(BUILD_LIBRETRO)
845 file(GLOB RETRO_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/libretro/*.c)
846 add_library(${BINARY_NAME}_libretro SHARED ${CORE_SRC} ${RETRO_SRC})
847 set_target_properties(${BINARY_NAME}_libretro PROPERTIES PREFIX "" COMPILE_DEFINITIONS "COLOR_16_BIT;COLOR_5_6_5;DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=2")
848 target_link_libraries(${BINARY_NAME}_libretro ${OS_LIB})
849 install(TARGETS ${BINARY_NAME}_libretro LIBRARY DESTINATION ${LIBRETRO_LIBDIR} COMPONENT ${BINARY_NAME}_libretro NAMELINK_SKIP)
850endif()
851
852if(BUILD_OPENEMU)
853 find_library(FOUNDATION Foundation)
854 find_library(OPENEMUBASE OpenEmuBase)
855 file(GLOB OE_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/*.m)
856 add_library(${BINARY_NAME}-openemu MODULE ${CORE_SRC} ${OS_SRC})
857 set_target_properties(${BINARY_NAME}-openemu PROPERTIES
858 MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/openemu/Info.plist.in
859 BUNDLE TRUE
860 BUNDLE_EXTENSION oecoreplugin
861 OUTPUT_NAME ${PROJECT_NAME}
862 COMPILE_DEFINITIONS "DISABLE_THREADING;${OS_DEFINES};${FUNCTION_DEFINES};MINIMAL_CORE=1")
863 target_link_libraries(${BINARY_NAME}-openemu ${OS_LIB} ${FOUNDATION} ${OPENEMUBASE})
864 install(TARGETS ${BINARY_NAME}-openemu LIBRARY DESTINATION ${OE_LIBDIR} COMPONENT ${BINARY_NAME}.oecoreplugin NAMELINK_SKIP)
865endif()
866
867if(BUILD_SDL)
868 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/sdl ${CMAKE_CURRENT_BINARY_DIR}/sdl)
869 # The SDL platform CMakeLists could decide to disable SDL, so check again before adding the define.
870 if(BUILD_SDL)
871 add_definitions(-DBUILD_SDL)
872 endif()
873endif()
874
875if(BUILD_QT)
876 add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/src/platform/qt ${CMAKE_CURRENT_BINARY_DIR}/qt)
877endif()
878
879if(BUILD_PERF)
880 set(PERF_SRC ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/perf-main.c)
881 if(UNIX AND NOT APPLE)
882 list(APPEND PERF_LIB rt)
883 endif()
884
885 add_executable(${BINARY_NAME}-perf ${PERF_SRC})
886 target_link_libraries(${BINARY_NAME}-perf ${BINARY_NAME} ${PERF_LIB} ${OS_LIB})
887 set_target_properties(${BINARY_NAME}-perf PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
888 install(TARGETS ${BINARY_NAME}-perf DESTINATION bin COMPONENT ${BINARY_NAME}-perf)
889 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/perf.py DESTINATION "${CMAKE_INSTALL_LIBDIR}/${BINARY_NAME}" COMPONENT ${BINARY_NAME}-perf)
890endif()
891
892if(BUILD_TEST)
893 add_executable(${BINARY_NAME}-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/fuzz-main.c)
894 target_link_libraries(${BINARY_NAME}-fuzz ${BINARY_NAME})
895 set_target_properties(${BINARY_NAME}-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
896 add_executable(tbl-fuzz ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/test/tbl-fuzz-main.c)
897 target_link_libraries(tbl-fuzz ${BINARY_NAME})
898 set_target_properties(tbl-fuzz PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
899 install(TARGETS ${BINARY_NAME}-fuzz tbl-fuzz DESTINATION bin COMPONENT ${BINARY_NAME}-test)
900endif()
901
902if(NOT USE_CMOCKA)
903 set(BUILD_SUITE OFF)
904endif()
905if(BUILD_SUITE)
906 enable_testing()
907 include_directories(AFTER ${CMOCKA_INCLUDE_DIRS})
908 link_directories(${CMOCKA_LIBRARY_DIRS})
909
910 foreach(TEST IN LISTS TEST_SRC)
911 string(REPLACE "${CMAKE_SOURCE_DIR}/src/" "" TEST_NAME "${TEST}")
912 string(REPLACE "/" "-" TEST_NAME "${TEST_NAME}")
913 string(REPLACE "-test" "" TEST_NAME "${TEST_NAME}")
914 string(REPLACE ".c" "" TEST_NAME "${TEST_NAME}")
915 add_executable(test-${TEST_NAME} ${TEST})
916 target_link_libraries(test-${TEST_NAME} ${BINARY_NAME} ${PLATFORM_LIBRARY} cmocka)
917 set_target_properties(test-${TEST_NAME} PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
918 add_test(${TEST_NAME} test-${TEST_NAME})
919 endforeach()
920endif()
921
922if(BUILD_EXAMPLE)
923 add_executable(${BINARY_NAME}-example-server ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/server.c)
924 target_link_libraries(${BINARY_NAME}-example-server ${BINARY_NAME})
925 set_target_properties(${BINARY_NAME}-example-server PROPERTIES COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}")
926
927 if(BUILD_SDL)
928 add_executable(${BINARY_NAME}-example-client ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/example/client-server/client.c)
929 target_link_libraries(${BINARY_NAME}-example-client ${BINARY_NAME} ${SDL_LIBRARY} ${SDLMAIN_LIBRARY} ${OPENGL_LIBRARY} ${OPENGLES2_LIBRARY})
930 set_target_properties(${BINARY_NAME}-example-client PROPERTIES
931 COMPILE_DEFINITIONS "${OS_DEFINES};${FEATURE_DEFINES};${FUNCTION_DEFINES}"
932 INCLUDE_DIRECTORIES "${SDL_INCLUDE_DIR};${CMAKE_CURRENT_SOURCE_DIR}/src;${CMAKE_CURRENT_SOURCE_DIR}/include")
933 endif()
934endif()
935
936configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/core/flags.h.in ${CMAKE_CURRENT_BINARY_DIR}/flags.h)
937install(FILES ${CMAKE_CURRENT_BINARY_DIR}/flags.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mgba COMPONENT lib${BINARY_NAME})
938
939# Packaging
940set(CPACK_PACKAGE_VERSION ${VERSION_STRING})
941set(CPACK_PACKAGE_VERSION_MAJOR ${LIB_VERSION_MAJOR})
942set(CPACK_PACKAGE_VERSION_MINOR ${LIB_VERSION_MINOR})
943set(CPACK_PACKAGE_VERSION_PATCH ${LIB_VERSION_PATCH})
944set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
945set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_SOURCE_DIR}/README.md)
946
947set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "mGBA Game Boy Advance Emulator")
948set(CPACK_PACKAGE_VENDOR "Jeffrey Pfau")
949set(CPACK_PACKAGE_CONTACT "Jeffrey Pfau <jeffrey@endrift.com>")
950set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
951set(CPACK_DEBIAN_PACKAGE_SECTION "games")
952
953SET(CPACK_DEB_COMPONENT_INSTALL ON)
954
955set(CPACK_STRIP_FILES ${BINARY_NAME})
956
957file(GLOB READMES ${CMAKE_CURRENT_SOURCE_DIR}/README*.md)
958install(FILES ${READMES} ${CMAKE_CURRENT_SOURCE_DIR}/CHANGES DESTINATION ${CMAKE_INSTALL_DOCDIR} COMPONENT lib${BINARY_NAME})
959
960include(CPack)
961
962# Summaries
963set(SUMMARY_GL_LIST)
964if(USE_EPOXY)
965 set(SUMMARY_GL_LIST "libepoxy")
966else()
967 if(BUILD_GL)
968 list(APPEND SUMMARY_GL_LIST "OpenGL")
969 endif()
970 if(BUILD_GLES2)
971 list(APPEND SUMMARY_GL_LIST "OpenGL|ES 2")
972 endif()
973endif()
974if(NOT SUMMARY_GL_LIST)
975 set(SUMMARY_GL OFF)
976else()
977 string(REPLACE ";" ", " SUMMARY_GL "${SUMMARY_GL_LIST}")
978endif()
979if(USE_LIBZIP)
980 set(SUMMARY_ZIP libzip)
981elseif(USE_MINIZIP)
982 set(SUMMARY_ZIP "minizip (external)")
983elseif(USE_ZLIB)
984 set(SUMMARY_ZIP "minizip (included)")
985else()
986 set(SUMMARY_ZIP OFF)
987endif()
988
989if(NOT QUIET)
990 message(STATUS "Build type: ${CMAKE_BUILD_TYPE}")
991 message(STATUS "Platforms:")
992 message(STATUS " Game Boy Advance: ${M_CORE_GBA}")
993 message(STATUS " Game Boy: ${M_CORE_GB}")
994 message(STATUS "Features:")
995 message(STATUS " Debuggers: ${USE_DEBUGGERS}")
996 if(NOT WIN32)
997 message(STATUS " CLI debugger: ${USE_EDITLINE}")
998 endif()
999 message(STATUS " GDB stub: ${USE_GDB_STUB}")
1000 message(STATUS " Video recording: ${USE_FFMPEG}")
1001 message(STATUS " GIF recording: ${USE_MAGICK}")
1002 message(STATUS " Screenshot/advanced savestate support: ${USE_PNG}")
1003 message(STATUS " ZIP support: ${SUMMARY_ZIP}")
1004 message(STATUS " 7-Zip support: ${USE_LZMA}")
1005 message(STATUS " SQLite3 game database: ${USE_SQLITE3}")
1006 message(STATUS " ELF loading support: ${USE_ELF}")
1007 message(STATUS " OpenGL support: ${SUMMARY_GL}")
1008 message(STATUS "Frontends:")
1009 message(STATUS " Qt: ${BUILD_QT}")
1010 message(STATUS " SDL (${SDL_VERSION}): ${BUILD_SDL}")
1011 message(STATUS " Profiling: ${BUILD_PERF}")
1012 message(STATUS " Test harness: ${BUILD_TEST}")
1013 message(STATUS " Test suite: ${BUILD_SUITE}")
1014 message(STATUS " Python bindings: ${BUILD_PYTHON}")
1015 message(STATUS " Examples: ${BUILD_EXAMPLE}")
1016 message(STATUS "Cores:")
1017 message(STATUS " Libretro core: ${BUILD_LIBRETRO}")
1018 if(APPLE)
1019 message(STATUS " OpenEmu core: ${BUILD_OPENEMU}")
1020 endif()
1021 message(STATUS "Libraries:")
1022 message(STATUS " Static: ${BUILD_STATIC}")
1023 message(STATUS " Shared: ${BUILD_SHARED}")
1024endif()